VBScript

Create JWT using a Brainpool EC Key

See more JSON Web Token (JWT) Examples

Demonstrates how to create a JWT using an EC private key. This is for JOSE headers having an "alg" member with any of the following values:

• BP160R1
• BP192R1
• BP224R1
• BP256R1
• BP320R1
• BP384R1
• BP512R1

This example also demonstrates how to include time constraints:

• nbf: Not Before Time
• exp: Expiration Time
• iat: Issue At Time

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' Demonstrates how to create a JWT using a brainpool EC private key.

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set privKey = CreateObject("Chilkat.PrivateKey")

' Load a brainpool EC key.
success = privKey.LoadPemFile("c:/qa_data/pem/ec_brainpool_privKey.pem")
If (success <> 1) Then
    outFile.WriteLine(privKey.LastErrorText)
    WScript.Quit
End If

' You can examine the curve name of the key you just loaded by getting the private in XML format:
' <ECCKeyValue curve="CURVE_NAME">...</ECCKeyValue>
outFile.WriteLine(privKey.GetXml())

set jwt = CreateObject("Chilkat.Jwt")

' Build the JOSE header
set jose = CreateObject("Chilkat.JsonObject")
' Use the brainpool curve name matching the private key you just loaded.
' Use "BP256R1", or "BP384R1", etc.   
success = jose.AppendString("alg","BP256R1")
success = jose.AppendString("typ","JWT")

' Now build the JWT claims (also known as the payload)
set claims = CreateObject("Chilkat.JsonObject")
success = claims.AppendString("iss","http://example.org")
success = claims.AppendString("sub","John")
success = claims.AppendString("aud","http://example.com")

' Set the timestamp of when the JWT was created to now.
curDateTime = jwt.GenNumericDate(0)
success = claims.AddIntAt(-1,"iat",curDateTime)

' Set the "not process before" timestamp to now.
success = claims.AddIntAt(-1,"nbf",curDateTime)

' Set the timestamp defining an expiration time (end time) for the token
' to be now + 1 hour (3600 seconds)
success = claims.AddIntAt(-1,"exp",curDateTime + 3600)

' Produce the smallest possible JWT:
jwt.AutoCompact = 1

' Create the JWT token.  This is where the ECC signature is created.
token = jwt.CreateJwtPk(jose.Emit(),claims.Emit(),privKey)

outFile.WriteLine(token)

outFile.Close