VBScript

Create a JWS Using ECDSA P-256 SHA-256

See more JSON Web Signatures (JWS) Examples

Creates and validates a JSON Web Signature (JWS) that uses ECDSA P-256 SHA-256 VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Note: This example requires Chilkat v9.5.0.66 or greater.

' Use the following ECC key loaded from JWK format.
set sbJwk = CreateObject("Chilkat.StringBuilder")
success = sbJwk.Append("{""kty"":""EC"",")
success = sbJwk.Append("""crv"":""P-256"",")
success = sbJwk.Append("""x"":""f83OJ3D2xF1Bg8vub9tLe1gHMzV76e8Tus9uPHvRVEU"",")
success = sbJwk.Append("""y"":""x_FEzRu9m36HLN_tue659LNpXW6pCyStikYjKIWI5a0"",")
success = sbJwk.Append("""d"":""jpsQnnGQmL-YBIffH1136cspYG6-0iY7X1fCE9-E9LI""")
success = sbJwk.Append("}")

set eccKey = CreateObject("Chilkat.PrivateKey")
' Note: This example loads the ECDSA key from JWK format.  Any format can be loaded
' into the private key object. (See the online reference documentation..)
success = eccKey.LoadJwk(sbJwk.GetAsString())
If (success = 0) Then
    outFile.WriteLine(eccKey.LastErrorText)
    WScript.Quit
End If

' Create the JWS Protected Header
set jwsProtHdr = CreateObject("Chilkat.JsonObject")
success = jwsProtHdr.AppendString("alg","ES256")

set jws = CreateObject("Chilkat.Jws")

' Set the protected header:
signatureIndex = 0
success = jws.SetProtectedHeader(signatureIndex,jwsProtHdr)

' Set the ECC key:
success = jws.SetPrivateKey(signatureIndex,eccKey)

' Set the payload.
bIncludeBom = 0
payloadStr = "In our village, folks say God crumbles up the old moon into stars."
success = jws.SetPayload(payloadStr,"utf-8",bIncludeBom)

' Create the JWS
' By default, the compact serialization is used.
jwsCompact = jws.CreateJws()
If (jws.LastMethodSuccess = 0) Then
    outFile.WriteLine(jws.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("JWS: " & jwsCompact)

' Note: ECC signatures use random values, so the output will be different each time a signature is produced.
' sample output:
' JWS: eyJhbGciOiJFUzI1NiJ9.SW4gb3VyIHZpbGxhZ2UsIGZvbGtzIHNheSBHb2QgY3J1bWJsZXMgdXAgdGhlIG9sZCBtb29uIGludG8gc3RhcnMu.J6EGTNkeuEjehHHBu0SOKzifm8r35wbx49A5964pxzB7gannyZZPMkK7vmlaPJ-K8Xmm8cZsQySAPC12Xd8avw

' Now load the JWS, validate, and recover the original text.
set jws2 = CreateObject("Chilkat.Jws")

' Load the JWS.
success = jws2.LoadJws(jwsCompact)

set eccPubKey = CreateObject("Chilkat.PublicKey")
success = eccKey.ToPublicKey(eccPubKey)

' Set the ECC public key used for validation.
signatureIndex = 0
success = jws2.SetPublicKey(signatureIndex,eccPubKey)

' Validate the 1st (and only) signature at index 0..
v = jws2.Validate(signatureIndex)
If (v < 0) Then
    ' Perhaps Chilkat was not unlocked or the trial expired..
    outFile.WriteLine("Method call failed for some other reason.")
    outFile.WriteLine(jws2.LastErrorText)
    WScript.Quit
End If

If (v = 0) Then
    outFile.WriteLine("Invalid signature.  The ECC key was incorrect, the JWS was invalid, or both.")
    WScript.Quit
End If

' If we get here, the signature was validated..
outFile.WriteLine("Signature validated.")

' Recover the original content:
outFile.WriteLine(jws2.GetPayload("utf-8"))

' Examine the protected header:
set joseHeader = CreateObject("Chilkat.JsonObject")
success = jws2.GetProtectedH(signatureIndex,joseHeader)
joseHeader.EmitCompact = 0

outFile.WriteLine("Protected (JOSE) header:")
outFile.WriteLine(joseHeader.Emit())

' Output:

' Signature validated.
' In our village, folks say God crumbles up the old moon into stars.
' Protected (JOSE) header:
' { 
'   "alg": "ES256"
' }

outFile.Close