Set the Optional JWS Unprotected Header

See more JSON Web Signatures (JWS) Examples

Demonstrates Jws.SetUnprotectedHeader, which sets the optional unprotected header for a signature.

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

set jws = CreateObject("Chilkat.Jws")

'  Protected header specifying HMAC-SHA256.
set header = CreateObject("Chilkat.JsonObject")
success = header.UpdateString("alg","HS256")
success = jws.SetProtectedHeader(0,header)
If (success = 0) Then
    outFile.WriteLine(jws.LastErrorText)
    WScript.Quit
End If

'  Set the optional unprotected header for signature 0.  Unlike the protected header, it is not
'  covered by the signature.  It is carried in the JSON serialization forms of a JWS.
set unprotected = CreateObject("Chilkat.JsonObject")
success = unprotected.UpdateString("kid","signer-key-1")
success = jws.SetUnprotectedHeader(0,unprotected)
If (success = 0) Then
    outFile.WriteLine(jws.LastErrorText)
    WScript.Quit
End If

bIncludeBom = 0
success = jws.SetPayload("This is the content to sign.","utf-8",bIncludeBom)
If (success = 0) Then
    outFile.WriteLine(jws.LastErrorText)
    WScript.Quit
End If

base64Key = "YWJjZGVmZ2hpamtsbW5vcHFyc3R1dnd4eXowMTIzNDU="
success = jws.SetMacKey(0,base64Key,"base64")
If (success = 0) Then
    outFile.WriteLine(jws.LastErrorText)
    WScript.Quit
End If

'  Because an unprotected header is present, the JWS is produced in a JSON serialization form.
jwsJson = jws.CreateJws()
If (jws.LastMethodSuccess = 0) Then
    outFile.WriteLine(jws.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine(jwsJson)

outFile.Close