VBScript

Encrypt Content to a JWE

See more JSON Web Encryption (JWE) Examples

Demonstrates Jwe.Encrypt, which encrypts a string and returns the resulting JWE. The charset argument converts the text to bytes before encryption.

Background. JWE (JSON Web Encryption) protects content with a content-encryption algorithm (the header enc value) while the content-encryption key is managed by the key-management algorithm (the header alg value). This example uses AES key wrapping with a symmetric wrapping key.

Chilkat VBScript Downloads

Download Chilkat for VBScript

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

set jwe = CreateObject("Chilkat.Jwe")

'  Set the JWE protected header, specifying the key-management algorithm (alg) and the content-
'  encryption algorithm (enc).
set header = CreateObject("Chilkat.JsonObject")
success = header.UpdateString("alg","A256KW")
success = header.UpdateString("enc","A256GCM")
success = jwe.SetProtectedHeader(header)
If (success = 0) Then
    outFile.WriteLine(jwe.LastErrorText)
    WScript.Quit
End If

'  The 256-bit key-wrapping key (base64) for recipient index 0.  In production, obtain the key
'  from a secure source rather than hard-coding it.
base64Key = "YWJjZGVmZ2hpamtsbW5vcHFyc3R1dnd4eXowMTIzNDU="
success = jwe.SetWrappingKey(0,base64Key,"base64")
If (success = 0) Then
    outFile.WriteLine(jwe.LastErrorText)
    WScript.Quit
End If

'  Encrypt the content.  The 2nd argument is the charset used to convert the text to bytes.  The
'  returned string is the JWE (compact serialization by default).
jweCompact = jwe.Encrypt("This is the secret content.","utf-8")
If (jwe.LastMethodSuccess = 0) Then
    outFile.WriteLine(jwe.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine(jweCompact)

outFile.Close