VBScript

Check if Integer Exists at JSON Path

Demonstrates how to get an integer value at a JSON path, and how to check to see if it exists. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

set json = CreateObject("Chilkat.JsonObject")

' First build simple JSON..
success = json.UpdateInt("test.abc",100)

json.EmitCompact = 0
outFile.WriteLine(json.Emit())

' This is our JSON:
' {
'   "test": {
'     "abc": 100,
'   }
' }

path = "test.notHere"

' The call to IntOf will return 0, because it's not present.
' But how do we know if it really was present, and the value was truly 0?
val = json.IntOf(path)
outFile.WriteLine("val = " & val)

' We cannot use LastMethodSuccess because LastMethodSuccess only applies
' to methods that:
' - return a string
' - return a new Chilkat object, binary bytes, or a date/time.
' - returns a boolean status where 1 = success and 0 = failed.
' - returns an integer where failure is defined by a return value less than zero.
' The IntOf method fits none of these requirements, and therefore the LastMethodSuccess 
' is not a valid indicator..
wasFound = json.LastMethodSuccess
outFile.WriteLine("wasFound = " & wasFound & " (not a valid indicator)")

' Instead, if the returned value is 0, we can double-check to see if the member was truly there..
If (val = 0) Then
    wasFound = json.HasMember(path)
    outFile.WriteLine("wasFound = " & wasFound)
    If (wasFound = 1) Then
        outFile.WriteLine("The value was present and is 0.")
    Else
        outFile.WriteLine("no member is present at test.notHere")
    End If

Else
    outFile.WriteLine("val = " & val)
End If

' Alternatively, you could check to see if the member exists beforehand..
If (json.HasMember(path) = 1) Then
    outFile.WriteLine("val = " & json.IntOf(path))
Else
    outFile.WriteLine("no member at " & path)
End If


outFile.Close