VBScript

Create Egypt ITIDA CAdES-BES .p7s Signature (with strings in-memory)

See more Egypt ITIDA Examples

Demonstrates how to create a .p7s signature that fits Egypt's ITIDA requirements.

Note: This example requires Chilkat v9.5.0.75 or greater.

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set crypt = CreateObject("Chilkat.Crypt2")

set cert = CreateObject("Chilkat.Cert")

' There are many ways to load the certificate.  
' This example was created for a customer using an ePass2003 USB token.
' Assuming the USB token is the only source of a hardware-based private key..
success = cert.LoadFromSmartcard("")
If (success <> 1) Then
    outFile.WriteLine(cert.LastErrorText)
    WScript.Quit
End If

' Tell the crypt component to use this cert.
success = crypt.SetSigningCert(cert)
If (success <> 1) Then
    outFile.WriteLine(crypt.LastErrorText)
    WScript.Quit
End If

set cmsOptions = CreateObject("Chilkat.JsonObject")
' Setting "DigestData" causes OID 1.2.840.113549.1.7.5 (digestData) to be used.
success = cmsOptions.UpdateBool("DigestData",1)
success = cmsOptions.UpdateBool("OmitAlgorithmIdNull",1)
crypt.CmsOptions = cmsOptions.Emit()

' The CadesEnabled property applies to all methods that create CMS/PKCS7 signatures. 
' To create a CAdES-BES signature, set this property equal to true. 
crypt.CadesEnabled = 1

crypt.HashAlgorithm = "sha256"

set jsonSigningAttrs = CreateObject("Chilkat.JsonObject")
success = jsonSigningAttrs.UpdateInt("contentType",1)
success = jsonSigningAttrs.UpdateInt("signingTime",1)
success = jsonSigningAttrs.UpdateInt("messageDigest",1)
success = jsonSigningAttrs.UpdateInt("signingCertificateV2",1)
crypt.SigningAttributes = jsonSigningAttrs.Emit()

' By default, all the certs in the chain of authentication are included in the signature.
' If desired, we can choose to only include the signing certificate:
crypt.IncludeCertChain = 0

' Make sure we sign the utf-8 byte representation of the JSON string
crypt.Charset = "utf-8"

' Create the CAdES-BES signature.
textToSign = """issuer""""address""""branchID""""0""""country""""EG""""regionCity..."

crypt.EncodingMode = "base64"
sigBase64 = crypt.SignStringENC(textToSign)
If (crypt.LastMethodSuccess = 0) Then
    outFile.WriteLine(crypt.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Base64 signature:")
outFile.WriteLine(sigBase64)

outFile.Close