(VBScript) Read IMAP Email Headers

Call FetchHeaders to download only the email headers.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set imap = CreateObject("Chilkat_9_5_0.Imap")

' Connect to an IMAP server.
' Use TLS
imap.Ssl = 1
imap.Port = 993
success = imap.Connect("imap.someMailServer.com")
If (success <> 1) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' Login
success = imap.Login("****","****")
If (success <> 1) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' Select an IMAP mailbox
success = imap.SelectMailbox("Inbox")
If (success <> 1) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' We can choose to fetch UIDs or sequence numbers.
fetchUids = 1
' Get the message IDs of all the emails in the mailbox
' messageSet is a Chilkat_9_5_0.MessageSet
Set messageSet = imap.Search("ALL",fetchUids)
If (imap.LastMethodSuccess <> 1) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' When downloading headers, each email object contains
' (obviously) the headers, but the body will be missing.
' Also, attachments will not be included.  However, it is
' possible to get information about the attachments
' as well as the complete size of the email.

' bundle is a Chilkat_9_5_0.EmailBundle
Set bundle = imap.FetchHeaders(messageSet)
If (imap.LastMethodSuccess <> 1) Then

    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' Loop over the email objects and display information
' about each:

For i = 0 To bundle.MessageCount - 1

    ' email is a Chilkat_9_5_0.Email
    Set email = bundle.GetEmail(i)

    ' Display the From and Subject
    outFile.WriteLine(email.From)
    outFile.WriteLine(email.Subject)

    ' Display the recipients:

    For j = 0 To email.NumTo - 1
        name = email.GetToName(j)
        addr = email.GetToAddr(j)
        outFile.WriteLine(name & ", " & addr)
    Next
    For j = 0 To email.NumCC - 1
        name = email.GetCcName(j)
        addr = email.GetCcAddr(j)
        outFile.WriteLine(name & ", " & addr)
    Next

    ' Show the total size of the email, including body and attachments:
    outFile.WriteLine(email.Size)

    ' When a full email is downloaded, we would use the
    ' email.NumAttachments property in conjunction with the
    ' email.GetMailAttach* methods.
    ' However, when an email object contains only the header,
    ' we need to access the attachment info differently:
    numAttach = imap.GetMailNumAttach(email)
    For j = 0 To numAttach - 1
        outFile.WriteLine(imap.GetMailAttachFilename(email,j))
        attachSize = imap.GetMailAttachSize(email,j)
        outFile.WriteLine("    size = " & attachSize & " bytes")
    Next

    outFile.WriteLine("--")

Next

' Disconnect from the IMAP server.
success = imap.Disconnect()


outFile.Close