VBScript

IMAP Login Secure

Demonstrates how to use the LoginSecure method introduced in Chilkat v9.5.0.71. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set imap = CreateObject("Chilkat.Imap")

' Connect to an IMAP server..
imap.Ssl = 1
imap.Port = 993
success = imap.Connect("imap.mail.me.com")
If (success <> 1) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' Imagine we've previously saved our encrypted login and password within a JSON config file
' that contains this:

' {
'   "imap_login": "fLkxsfnVaIWLiL/R32jo6g==",
'   "imap_password": "/NbaFBoCftBLFf8WBU9Xtw=="
' }

set json = CreateObject("Chilkat.JsonObject")
success = json.LoadFile("qa_data/passwords/imap.json")

set crypt = CreateObject("Chilkat.Crypt2")

' These are the encryption settings we previously used to encrypt the credentials within the JSON config file.
crypt.CryptAlgorithm = "aes"
crypt.CipherMode = "cbc"
crypt.KeyLength = 128
crypt.SetEncodedKey "000102030405060708090A0B0C0D0E0F","hex"
crypt.SetEncodedIV "000102030405060708090A0B0C0D0E0F","hex"
crypt.EncodingMode = "base64"

set ssLogin = CreateObject("Chilkat.SecureString")
set ssPassword = CreateObject("Chilkat.SecureString")

' Decrypt to the secure string.  (the strings will still held in memory encrypted, but are now encrypted using
' a randomly generated session key.)
success = crypt.DecryptSecureENC(json.StringOf("imap_login"),ssLogin)
success = crypt.DecryptSecureENC(json.StringOf("imap_password"),ssPassword)

' Pass the credentials to the LoginSecure method:
success = imap.LoginSecure(ssLogin,ssPassword)
If (success <> 1) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' ...

success = imap.Disconnect()

outFile.Close