VBScript Requires Chilkat v11.0.0+

Delete IMAP Email

To delete an email, the "Deleted" flag must be set to 1 for each message to be deleted. You must also call Expunge or ExpungeAndClose to remove the emails marked as deleted. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

'  This example assumes the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code.

'  This example deletes email matching a criteria from Inbox.
set imap = CreateObject("Chilkat.Imap")

'  Turn on session logging:
imap.KeepSessionLog = 1

'  Connect to an IMAP server.
'  Use TLS
imap.Ssl = 1
imap.Port = 993
success = imap.Connect("imap.example.com")
If (success = 0) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

'  Login
success = imap.Login("myLogin","myPassword")
If (success = 0) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

'  Select an IMAP mailbox
success = imap.SelectMailbox("Inbox")
If (success = 0) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

fetchUids = 1
'  Get the message IDs for all emails having "FTP2" in the subject.
set messageSet = CreateObject("Chilkat.MessageSet")
success = imap.QueryMbx("SUBJECT FTP2",fetchUids,messageSet)
If (success = 0) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

'  Set the Deleted flag for each message:
success = imap.SetFlags(messageSet,"Deleted",1)
If (success = 0) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

'  Expunge and close the mailbox.
success = imap.ExpungeAndClose()
If (success = 0) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

'  Display the session log.
outFile.WriteLine(imap.SessionLog)

'  Disconnect from the IMAP server.
success = imap.Disconnect()

outFile.Close