VBScript

HTTPS Upload with Client SSL Certificate

This example shows how to use a client-side certificate with HTTPS to upload one or more files to a web server. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set http = CreateObject("Chilkat.Http")

set req = CreateObject("Chilkat.HttpRequest")
req.HttpVerb = "POST"
req.ContentType = "multipart/form-data"
req.Path = "rcvFormDataUpload.aspx"

' Send an "Expect: 100-continue" header in the request.
' This causes the HTTP server to end a 100-continue response
' immediately after receiving the HTTP header.  The client
' (Chilkat) will receive this intermediate response, and if
' it's not an error response, it knows that the HTTP server will
' accept the data that is forthcoming.
' The alternative is to get an error response after trying to upload
' the entire contents of the files.
req.AddHeader "Expect","100-continue"

' Call AddFileForUpload2 for each file to be uploaded in the HTTP multipart/form-data POST
' To allow Chilkat to determine the content-type automatically based on file-extension,
' call AddFileForUpload instead.

' The 1st arg is the filename passed in the HTTP request.
' The 2nd arg is the path in the local filesytem.
' The file is not loaded into memory.  It is streamed directly from the file
' when the HTTP POST is sent.
success = req.AddFileForUpload2("starfish.jpg","c:/qa_data/starfish.jpg","image/jpg")
If (success = 0) Then
    outFile.WriteLine(req.LastErrorText)
    WScript.Quit
End If

success = req.AddFileForUpload("something.pdf","c:/qa_data/something.pdf")
If (success = 0) Then
    outFile.WriteLine(req.LastErrorText)
    WScript.Quit
End If

' Its also possible to add a file from a string:
success = req.AddStringForUpload("test.xml","test.xml","<abc>This is the test.xml content</abc>","utf-8")
' We'll assume success since no files are involved..

set cert = CreateObject("Chilkat.Cert")
success = cert.LoadPfxFile("c:/qa_data/pfx/test.pfx","pfx_password")
If (success = 0) Then
    outFile.WriteLine(cert.LastErrorText)
    WScript.Quit
End If

' Set the certificate to be used for mutual TLS authentication
' (i.e. sets the client-side certificate for two-way TLS authentication)
success = http.SetSslClientCert(cert)
If (success = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

' This sends the HTTP request (with 3 files being uploaded) to
' https://www.example.com/rcvFormDataUpload.aspx
set resp = CreateObject("Chilkat.HttpResponse")
success = http.HttpSReq("www.example.com",443,1,req,resp)
If (success = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("HTTP response status: " & resp.StatusCode)
' See the online reference documentation for 
' other information that can be obtained from the response object.

outFile.Close