VBScript

QuickGetBd Example

The QuickGetBd method is called to send a GET request to download a binary target, such as PDF, zip, image file, etc. into a Chilkat BinData object. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set http = CreateObject("Chilkat.Http")
http.KeepResponseBody = 1

set bd = CreateObject("Chilkat.BinData")

' Download the contents of a PDF file into the bd object.
success = http.QuickGetBd("https://www.chilkatsoft.com/hello.pdf",bd)
If (success = 0) Then
    ' This will happen if the response status code was 400 or greater,
    ' or if the request could not be sent, or if no response was received.
    ' 
    ' In other words, success will only be 1 if bd contains the desired content at the URL (not an error response).
    statusCode = http.LastStatus
    outFile.WriteLine("Response status: " & statusCode)

    If (statusCode = 0) Then
        ' There was an error in communications.  
        outFile.WriteLine(http.LastErrorText)
    Else
        ' We received a response status code indicating failure.
        ' Examine the response body.
        outFile.WriteLine(http.LastResponseBody)
    End If

    WScript.Quit
End If

' Load the downloaded PDF into a Chilkat PDF object.
set pdf = CreateObject("Chilkat.Pdf")
success = pdf.LoadBd(bd)
If (success = 0) Then
    outFile.WriteLine(pdf.LastErrorText)
    WScript.Quit
End If

' ...

outFile.WriteLine("Success.")

outFile.Close