VBScript

Fetch Web Pages from Local Cache

See more HTTP Examples

Demonstrates how to keep a local cache to avoid re-fetching web pages. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set http = CreateObject("Chilkat.Http")

' Define a cache directory and set the number of levels based on the anticipated size of the cache.
http.AddCacheRoot "c:/example/httpCache/"

' up to 256 sub-directories under the cache root will be created as needed to hold cached GET's.
http.NumCacheLevels = 1

' Tell the http object to fetch from the cache if possible.
http.FetchFromCache = 1

' Also tell the http object to update the cache with newly fetched pages.
http.UpdateCache = 1

' This HTTP GET should result in a cache file getting created.
html = http.QuickGetStr("https://www.google.com/")
If (http.LastMethodSuccess = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

' The 1st GET was not from cache:
outFile.WriteLine("Fetched from cache: " & http.LastFromCache)

' Fetching again will cause the page to be delivered from our local cache.
html = http.QuickGetStr("https://www.google.com/")
If (http.LastMethodSuccess = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

' The 2nd GET is from cache:
outFile.WriteLine("Fetched from cache: " & http.LastFromCache)

outFile.Close