Chilkat Examples

ChilkatHOME.NET Core C#Android™AutoItCC#C++Chilkat2-PythonCkPythonClassic ASPDataFlexDelphi ActiveXDelphi DLLGoJavaLianjaMono C#Node.jsObjective-CPHP ActiveXPHP ExtensionPerlPowerBuilderPowerShellPureBasicRubySQL ServerSwift 2Swift 3,4,5...TclUnicode CUnicode C++VB.NETVBScriptVisual Basic 6.0Visual FoxProXojo Plugin

VBScript Examples

Web API Categories

ASN.1
AWS KMS
AWS Misc
Amazon EC2
Amazon Glacier
Amazon S3
Amazon S3 (new)
Amazon SES
Amazon SNS
Amazon SQS
Async
Azure Cloud Storage
Azure Key Vault
Azure Service Bus
Azure Table Service
Base64
Bounced Email
Box
CAdES
CSR
CSV
Certificates
Code Signing
Compression
DKIM / DomainKey
DNS
DSA
Diffie-Hellman
Digital Signatures
Dropbox
Dynamics CRM
EBICS
ECC
Ed25519
Email Object
Encryption
FTP
FileAccess
Firebase
GMail REST API
GMail SMTP/IMAP/POP
Geolocation
Google APIs
Google Calendar
Google Cloud SQL
Google Cloud Storage
Google Drive
Google Photos
Google Sheets
Google Tasks
Gzip
HTML-to-XML/Text
HTTP

HTTP Misc
IMAP
JSON
JSON Web Encryption (JWE)
JSON Web Signatures (JWS)
JSON Web Token (JWT)
Java KeyStore (JKS)
MHT / HTML Email
MIME
MS Storage Providers
Microsoft Graph
Misc
NTLM
OAuth1
OAuth2
OIDC
Office365
OneDrive
OpenSSL
Outlook
Outlook Calendar
Outlook Contact
PDF Signatures
PEM
PFX/P12
PKCS11
POP3
PRNG
REST
REST Misc
RSA
SCP
SCard
SFTP
SMTP
SSH
SSH Key
SSH Tunnel
ScMinidriver
SharePoint
SharePoint Online
Signing in the Cloud
Socket/SSL/TLS
Spider
Stream
Tar Archive
ULID/UUID
Upload
WebSocket
XAdES
XML
XML Digital Signatures
XMP
Zip
curl

 

 

 

(VBScript) HttpPostJson2Async Example

Demonstrates use of the HttpPostJson2Async method.

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

'  This requires the Chilkat API to have been previously unlocked.
'  See Global Unlock Sample for sample code

'  See PostJson2 Example for the synchronous equivalent of this example.

set http = CreateObject("Chilkat_9_5_0.Http")

'  Sends a POST equivalent to the following CURL command:

'  curl -X POST https://sandbox.plaid.com/institutions/get \
'    -H 'content-type: application/json' \
'    -d '{
'      "client_id": String,
'      "secret":String,
'      "count": Number,
'      "offset": Number
'    }'

'  Suppress some default headers that would automatically added..
http.AcceptCharset = ""
http.UserAgent = ""
http.AcceptLanguage = ""
http.AllowGzip = 0

jsonBody = "{""client_id"": ""PLAID_CLIENT_ID"", ""secret"":""PLAID_SECRET"", ""count"": 10, ""offset"": 0}"
' task is a Chilkat_9_5_0.Task
Set task = http.PostJson2Async("https://sandbox.plaid.com/institutions/get","application/json",jsonBody)
If (http.LastMethodSuccess = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

'  Start the background task.
success = task.Run()
If (Not success) Then
    outFile.WriteLine(task.LastErrorText)

    WScript.Quit
End If

'  The application is now free to do anything else
'  while the HTTP POST is in progress

'  For this example, we'll simply sleep and periodically
'  check to see if the HTTP POST is finished.
Do While task.Finished <> 1
    '  Sleep 100 ms.
    task.SleepMs 100
Loop

'  When we get here, the task is either finished successfully or not, or was canceled/aborted.

'  If the task was "canceled", it was canceled prior to actually starting.  This could
'  happen if the task was canceled while waiting in a thread pool queue to be scheduled by Chilkat's
'  background thread pool scheduler.

'  If the task was "aborted", it indicates that it was canceled while running in a background thread.
'  The ResultErrorText will likely indicate that the task was aborted.

'  If the task "completed", then it ran to completion, but the actual success/failure of the method
'  is determined by getting the result of the underlying method call.
'  A task status of 7 indicates completion.
If (task.StatusInt <> 7) Then
    outFile.WriteLine("Task did not complete.")
    outFile.WriteLine("task status: " & task.Status)

    WScript.Quit
End If

'  When called synchronously, the PostJson2 method returns an HTTP response object,
'  unless the method failed and there was no response to be had.
'  Check to see if PostJson2 method failed (and thus there is no response object).
If (task.TaskSuccess = 0) Then
    outFile.WriteLine("The underlying task failed, and there is no HTTP response object.")
    outFile.WriteLine("The LastErrorText for the underlying method call is:")
    outFile.WriteLine(task.ResultErrorText)

    WScript.Quit
End If

'  To get the HTTP response object, create a new instance and load it with the result from the task.
set resp = CreateObject("Chilkat_9_5_0.HttpResponse")
success = resp.LoadTaskResult(task)

statusCode = resp.StatusCode
outFile.WriteLine("Response status code = " & statusCode)

'  Examine the JSON response..
set json = CreateObject("Chilkat_9_5_0.JsonObject")
success = json.Load(resp.BodyStr)
json.EmitCompact = 0
outFile.WriteLine("JSON Response Body:")
outFile.WriteLine(json.Emit())

outFile.Close

 

© 2000-2024 Chilkat Software, Inc. All Rights Reserved.