VBScript

Decompress Gzip Data In-Place Using BinData

See more Gzip Examples

This example demonstrates how to use the UncompressBd method to decompress Gzip data stored in a BinData object.

The compressed .gz file is first loaded into memory. The UncompressBd method then decompresses the data in-place, meaning the original compressed bytes in the BinData object are replaced with the uncompressed data.

After decompression, the example writes the resulting data to a file. This approach is useful when working entirely in memory before saving or further processing the uncompressed data.

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example demonstrates how to decompress Gzip data stored in a BinData object.
' The decompression is done in-place, replacing the compressed data with the original data.

set gzip = CreateObject("Chilkat.Gzip")
set bd = CreateObject("Chilkat.BinData")

' Load a .gz file into BinData:
success = bd.LoadFile("example.txt.gz")
If (success = 0) Then
    outFile.WriteLine(bd.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Compressed size (bytes): " & bd.NumBytes)

' Uncompress the data in-place:
success = gzip.UncompressBd(bd)
If (success = 0) Then
    outFile.WriteLine(gzip.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Decompressed size (bytes): " & bd.NumBytes)

' Save the uncompressed data to a file:
success = bd.WriteFile("example.txt")
If (success = 0) Then
    outFile.WriteLine(bd.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("File successfully uncompressed to example.txt")

outFile.Close