VBScript

batchGet (Read Multiple Ranges)

See more Google Sheets Examples

Reads multiple ranges from a Google Sheets spreadsheet in one GET request. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' This example uses a previously obtained access token having permission for the 
' Google Sheets scope.

' In this example, Get Google Sheets OAuth2 Access Token, the access
' token was saved to a JSON file.  This example fetches the access token from the file..
set jsonToken = CreateObject("Chilkat.JsonObject")
success = jsonToken.LoadFile("qa_data/tokens/googleSheets.json")
If (jsonToken.HasMember("access_token") = 0) Then
    outFile.WriteLine("No access token found.")
    WScript.Quit
End If

' We'll be sending a GET request with query params to this URL:  https://sheets.googleapis.com/v4/spreadsheets/spreadsheetId/values:batchGet?ranges=Sheet1!A1:A2&ranges=Sheet1!B1:B2
' The domain is "sheets.googleapis.com"
' The path is "/v4/spreadsheets/spreadsheetId/values:batchGet"
set req = CreateObject("Chilkat.HttpRequest")
req.Path = "/v4/spreadsheets/spreadsheetId/values:batchGet"
req.HttpVerb = "GET"
' Add each range to fetch.
req.AddParam "ranges","Sheet1!A1:A2"
req.AddParam "ranges","Sheet1!B1:B2"

set http = CreateObject("Chilkat.Http")
http.AuthToken = jsonToken.StringOf("access_token")

' 443 is the SSL/TLS port for HTTPS.
set resp = CreateObject("Chilkat.HttpResponse")
success = http.HttpSReq("sheets.googleapis.com",443,1,req,resp)
If (success = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine(resp.BodyStr)

set json = CreateObject("Chilkat.JsonObject")
success = json.Load(resp.BodyStr)

' A sample response is shown below.
' To generate the parsing source code for a JSON response, paste
' the JSON into this online tool: Generate JSON parsing code

' {
'   "spreadsheetId": "1_SO2L-Y6nCayNpNppJLF0r9yHB2UnaCleGCKeE4O0SA",
'   "valueRanges": [
'     {
'       "range": "Sheet1!A1:A2",
'       "majorDimension": "ROWS",
'       "values": [
'         [
'           "Item"
'         ],
'         [
'           "Wheel"
'         ]
'       ]
'     },
'     {
'       "range": "Sheet1!B1:B2",
'       "majorDimension": "ROWS",
'       "values": [
'         [
'           "Cost"
'         ],
'         [
'           "$20.50"
'         ]
'       ]
'     }
'   ]
' }

spreadsheetId = json.StringOf("spreadsheetId")
i = 0
count_i = json.SizeOfArray("valueRanges")
Do While i < count_i
    json.I = i
    range = json.StringOf("valueRanges[i].range")
    majorDimension = json.StringOf("valueRanges[i].majorDimension")
    j = 0
    count_j = json.SizeOfArray("valueRanges[i].values")
    Do While j < count_j
        json.J = j
        k = 0
        count_k = json.SizeOfArray("valueRanges[i].values[j]")
        Do While k < count_k
            json.K = k
            strVal = json.StringOf("valueRanges[i].values[j][k]")
            k = k + 1
        Loop
        j = j + 1
    Loop
    i = i + 1
Loop

outFile.Close