VBScript

Get Google API Access Token using JSON Private Key using NIST Time Server Date/Time

Demonstrates how to get a Google API access token using a JSON service account private key, using the NIST time server date/time rather than the local system date/time. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' First, let's get the current date/time from time-c.nist.gov
set socket = CreateObject("Chilkat.Socket")

' Connect to an NIST time server and read the current date/time
maxWaitMs = 8000
useTls = 0
success = socket.Connect("time-c.nist.gov",37,useTls,maxWaitMs)
If (success <> 1) Then
    outFile.WriteLine(socket.LastErrorText)
    WScript.Quit
End If

' The time server will send a big-endian 32-bit integer representing
' the number of seconds since since 00:00 (midnight) 1 January 1900 GMT.
' The ReceiveInt32 method will receive a 4-byte integer, but returns
' 1 or 0 to indicate success.  If successful, the integer
' is obtained via the ReceivedInt property.
bigEndian = 1
success = socket.ReceiveInt32(bigEndian)
If (success <> 1) Then
    outFile.WriteLine(socket.LastErrorText)
    WScript.Quit
End If

set dt = CreateObject("Chilkat.CkDateTime")
success = dt.SetFromNtpTime(socket.ReceivedInt)

' Show the current local date/time
bLocalTime = 1
outFile.WriteLine("Current local date/time: " & dt.GetAsRfc822(bLocalTime))

maxWaitMs = 10
success = socket.Close(maxWaitMs)

' ------------------------------------------------------------------------
' OK, we have the current date/time.  We'll use it to set the IAT property
' in the code below.

' First load the JSON key into a string.
set fac = CreateObject("Chilkat.FileAccess")
jsonKey = fac.ReadEntireTextFile("qa_data/googleApi/ChilkatTest-ab2ecd52ef98.json","utf-8")
If (fac.LastMethodSuccess <> 1) Then
    outFile.WriteLine(fac.LastErrorText)
    WScript.Quit
End If

' A JSON private key should look like this:

' 	{
' 	  "type": "service_account",
' 	  "project_id": "chilkattest-1350",
' 	  "private_key_id": "fa2e36ee26986eab628b59868af8bec1d1c64c38",
' 	  "private_key": "-----BEGIN PRIVATE KEY-----\nMIIEvgIjFa...28N64N2n1E4FYzBZjSdy\n-----END PRIVATE KEY-----\n",
' 	  "client_email": "598922945226-00rb0ppfg0sndajo6bhvd4v17jtj2d3a@developer.gserviceaccount.com",
' 	  "client_id": "598922945226-00rb0ppfg0snd9jo7bhvd4v17jtj2d3a.apps.googleusercontent.com",
' 	  "auth_uri": "https://accounts.google.com/o/oauth2/auth",
' 	  "token_uri": "https://accounts.google.com/o/oauth2/token",
' 	  "auth_provider_x509_cert_url": "https://www.googleapis.com/oauth2/v1/certs",
' 	  "client_x509_cert_url": "https://www.googleapis.com/robot/v1/metadata/x509/598922945226-00rb0ppfg0sndajo6bhvd4v17jtj2d3a%40developer.gserviceaccount.com"
' 	}

set gAuth = CreateObject("Chilkat.AuthGoogle")
gAuth.JsonKey = jsonKey

' Choose a scope.
gAuth.Scope = "https://www.googleapis.com/auth/cloud-platform"

' Request an access token that is valid for this many seconds.
gAuth.ExpireNumSeconds = 3600

' If the application is requesting delegated access:
' The email address of the user for which the application is requesting delegated access,
' then set the email address here. (Otherwise leave it empty.)
gAuth.SubEmailAddress = ""

' ------------------------------------------------------------------------
' Set the IAT using the date/time from the NIST time server.
unixTime = dt.GetAsUnixTime(0)
outFile.WriteLine("unixTime = " & unixTime)
gAuth.Iat = unixTime

' Connect to www.googleapis.com using TLS (TLS 1.2 is the default.)
' The Chilkat socket object is used so that the connection can be established
' through proxies or an SSH tunnel if desired.
set tlsSock = CreateObject("Chilkat.Socket")
success = tlsSock.Connect("www.googleapis.com",443,1,5000)
If (success <> 1) Then
    outFile.WriteLine(tlsSock.LastErrorText)
    WScript.Quit
End If

' Send the request to obtain the access token.
success = gAuth.ObtainAccessToken(tlsSock)
If (success <> 1) Then
    outFile.WriteLine(gAuth.LastErrorText)
    WScript.Quit
End If

' Examine the access token:
outFile.WriteLine("Access Token: " & gAuth.AccessToken)

outFile.Close