VBScript

Google Contacts - Delete a Contact

See more Google APIs Examples

Demonstrates how to delete a Google Contact. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' --------------------------------------------------------------------------------------------------------
' Note: The code for setting up the Chilkat REST object and making the initial connection can be done once.
' Once connected, the REST object may be re-used for many REST API calls.
' (It's a good idea to put the connection setup code in a separate function/subroutine.)
' --------------------------------------------------------------------------------------------------------

' It is assumed we previously obtained an OAuth2 access token.
' This example loads the JSON access token file 
' saved by this example: Get Google Contacts OAuth2 Access Token

set jsonToken = CreateObject("Chilkat.JsonObject")
success = jsonToken.LoadFile("qa_data/tokens/googleContacts.json")
If (success <> 1) Then
    outFile.WriteLine("Failed to load googleContacts.json")
    WScript.Quit
End If

set gAuth = CreateObject("Chilkat.AuthGoogle")
gAuth.AccessToken = jsonToken.StringOf("access_token")

set rest = CreateObject("Chilkat.Rest")

' Connect using TLS.
bAutoReconnect = 1
success = rest.Connect("www.google.com",443,1,bAutoReconnect)

' Provide the authentication credentials (i.e. the access token)
success = rest.SetAuthGoogle(gAuth)

' ----------------------------------------------
' OK, the REST connection setup is completed..
' ----------------------------------------------

' To update a contact, we'll first get the contact information
' to get the etag.

' To retrieve the contact, send the following:
' 	GET /m8/feeds/contacts/default/full/{contactId}
' 	GData-Version: 3.0

success = rest.AddHeader("GData-Version","3.0")

set sbPath = CreateObject("Chilkat.StringBuilder")
success = sbPath.Append("/m8/feeds/contacts/default/full/{contactId}")
' Get the contact having contactId = "5b6d64980b1ed462"
numReplacements = sbPath.Replace("{contactId}","5b6d64980b1ed462")

set sbResponseBody = CreateObject("Chilkat.StringBuilder")
success = rest.FullRequestNoBodySb("GET",sbPath.GetAsString(),sbResponseBody)
If (success <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' A successful response will have a status code equal to 200.
If (rest.ResponseStatusCode <> 200) Then
    outFile.WriteLine("response status code = " & rest.ResponseStatusCode)
    outFile.WriteLine("response status text = " & rest.ResponseStatusText)
    outFile.WriteLine("response header: " & rest.ResponseHeader)
    outFile.WriteLine("response body: " & sbResponseBody.GetAsString())
    WScript.Quit
End If

' If the 200 response was received, then the contacts XML is contained
' in the response body.
set xml = CreateObject("Chilkat.Xml")
success = xml.LoadSb(sbResponseBody,0)

outFile.WriteLine(xml.GetXml())
outFile.WriteLine("-------------------")

' Get the etag:
lastKnownEtag = xml.GetAttrValue("gd:etag")
outFile.WriteLine("lastKnownEtag = " & lastKnownEtag)
outFile.WriteLine("-------------------")

' To delete, send the following:

' 	DELETE /m8/feeds/contacts/default/full/{contactId}
' 	If-Match: {lastKnownEtag}
' 	GData-Version: 3.0

success = rest.ClearAllHeaders()
success = rest.AddHeader("If-Match",lastKnownEtag)
success = rest.AddHeader("GData-Version","3.0")

' The sbPath already contains the correct path..
success = rest.FullRequestNoBodySb("DELETE",sbPath.GetAsString(),sbResponseBody)
If (success <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' A successful response will have a status code equal to 200.
If (rest.ResponseStatusCode <> 200) Then
    outFile.WriteLine("response status code = " & rest.ResponseStatusCode)
    outFile.WriteLine("response status text = " & rest.ResponseStatusText)
    outFile.WriteLine("response header: " & rest.ResponseHeader)
    outFile.WriteLine("response body: " & sbResponseBody.GetAsString())
    outFile.WriteLine("request header: " & rest.LastRequestHeader)
    WScript.Quit
End If

' The response body for a successful DELETE is empty.
outFile.WriteLine("Response Body: (should be empty)")
outFile.WriteLine(sbResponseBody.GetAsString())
outFile.WriteLine("Success.")

outFile.Close