(VBScript) Refresh GMail IMAP OAuth2 Access Token

Demonstrates how to refresh an access token GMail IMAP read/write access.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' See Get GMail IMAP OAuth2 Access Token for Desktop App 
' for sample code showing how to obtain a GMail IMAP read/write access token.

' It is assumed we previously obtained an OAuth2 access token for GMail.

set jsonToken = CreateObject("Chilkat_9_5_0.JsonObject")
success = jsonToken.LoadFile("qa_data/tokens/_gmailFullAccess.json")
If (success <> 1) Then
    outFile.WriteLine("Failed to load _gmailFullAccess.json")
    WScript.Quit
End If

' The access token JSON looks something like this:

' 	{ 
' 	 "access_token": "abac.Ci-ZabcdF37-NUrmSzxbHxTsMbtlN-uPfabcdAQN_2ekzj0s5ofCzRabcdTDMGaa2Q",
' 	 "token_type": "Bearer",
' 	 "expires_in": 3600,
' 	 "refresh_token": "1/lEe5abcdNJ77eOSDBabcdkQGVmDalkwabcdR2Hatbo"
' 	}
' 

set oauth2 = CreateObject("Chilkat_9_5_0.OAuth2")

oauth2.TokenEndpoint = "https://www.googleapis.com/oauth2/v4/token"

' Replace these with actual values.
oauth2.ClientId = "GOOGLE-CLIENT-ID"
oauth2.ClientSecret = "GOOGLE-CLIENT-SECRET"

' Get the "refresh_token"
oauth2.RefreshToken = jsonToken.StringOf("refresh_token")

' Send the HTTP POST to refresh the access token..
success = oauth2.RefreshAccessToken()
If (success <> 1) Then
    outFile.WriteLine(oauth2.LastErrorText)
    WScript.Quit
End If

' The response contains a new access token, but we must keep
' our existing refresh token for when we need to refresh again in the future.
success = jsonToken.UpdateString("access_token",oauth2.AccessToken)

' Save the new JSON access token response to a file.
set sbJson = CreateObject("Chilkat_9_5_0.StringBuilder")
jsonToken.EmitCompact = 0
success = jsonToken.EmitSb(sbJson)
success = sbJson.WriteFile("qa_data/tokens/_gmailFullAccess.json","utf-8",0)

outFile.WriteLine("Access token refreshed!")
outFile.WriteLine("New Access Token = " & oauth2.AccessToken)

outFile.Close