(VBScript) Save String Variable to File on FTP Server

Save the contents of a string variable to a file on an FTP server.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set ftp = CreateObject("Chilkat_9_5_0.Ftp2")

ftp.Hostname = "ftp.example.com"
ftp.Username = "login"
ftp.Password = "password"

' Connect and login to the FTP server.
success = ftp.Connect()
If (success <> 1) Then
    outFile.WriteLine(ftp.LastErrorText)
    WScript.Quit
End If

' Change to the remote directory where the existing file is located.
success = ftp.ChangeRemoteDir("junk")
If (success <> 1) Then
    outFile.WriteLine(ftp.LastErrorText)
    WScript.Quit
End If

' Upload the contents of a string to a remote file.
fileContents = "To be, or not to be: that is the question."
remoteFilename = "hamletQuote.txt"

success = ftp.PutFileFromTextData(remoteFilename,fileContents)
If (success <> 1) Then
    outFile.WriteLine(ftp.LastErrorText)
    WScript.Quit
End If

success = ftp.Disconnect()

outFile.WriteLine("String Uploaded!")

outFile.Close