VBScript

FTP Sync Upload Tree w/ Must-Match Filename Constraints

See more FTP Examples

Demonstrates how synchronize a directory tree in the upload direction, but only upload files matching a set of wildcard filenames.

Note: This example requires Chilkat v9.5.0.76 or greater.

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set ftp = CreateObject("Chilkat.Ftp2")

ftp.Hostname = "ftp.something.com"
ftp.Username = "my_login"
ftp.Password = "my_password"

' Connect and login to the FTP server.
success = ftp.Connect()
If (success <> 1) Then
    outFile.WriteLine(ftp.LastErrorText)
    WScript.Quit
End If

' Set the current remote directory to the root of
' the tree to receive the uploaded files.
success = ftp.ChangeRemoteDir("/subDir1")
If (success <> 1) Then
    outFile.WriteLine(ftp.LastErrorText)
    WScript.Quit
End If

' Possible synchronization modes are:
' mode=0: Upload all files
' mode=1: Upload all files that do not exist on the FTP server.
' mode=2: Upload newer or non-existant files.
' mode=3: Upload only newer files. If a file does not already exist on the FTP server, it is not uploaded.
' mode=4: transfer missing files or files with size differences.
' mode=5: same as mode 4, but also newer files. 

' This example will upload all files, but only those files having filenames
' that match *.gif and *.eml

' Imagine our local directory tree has these files and directories:

' 	accentedLatin1.txt
' 	accentedUtf8.txt
' 	alice.key
' 	anter_cert.pem
' 	chiliPepper.gif
' 	helloWorld.pdf
' 	abc/chiliPepper.gif
' 	abc/ghk/
' 	data/chiliPepper.gif
' 	data/xyz/dkimHtmlBody.txt
' 	data/xyz/dkimVerifyTest.eml
' 	data/xyz/emailForCreateDsn.eml
' 	text/frenchUtf8.txt
' 	text/helloWorld.txt
' 	text/PolishEmailBody.txt
' 	text/something/

ftp.SyncMustMatch = "*.eml; *.gif"
mode = 0
success = ftp.SyncRemoteTree("c:/temp/subDir1",mode)
If (success <> 1) Then
    outFile.WriteLine(ftp.LastErrorText)
    WScript.Quit
End If

success = ftp.Disconnect()

' Show the files downloaded.
set st = CreateObject("Chilkat.StringTable")
ftp.GetSyncedFiles st

numFiles = st.Count
i = 0

Do While i < numFiles
    outFile.WriteLine(st.StringAt(i))
    i = i + 1
Loop

' Output showing the files uploaded:

' chiliPepper.gif
' abc/chiliPepper.gif
' data/chiliPepper.gif
' data/xyz/dkimVerifyTest.eml
' data/xyz/emailForCreateDsn.eml

outFile.Close