VBScript

FTP Sync Download Tree w/ Must-Match Directory Constraints

See more FTP Examples

Demonstrates how synchronize a directory tree in the download direction, but only entering directories matching a set of wildcard filenames.

Note: This example requires Chilkat v9.5.0.76 or greater.

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set ftp = CreateObject("Chilkat.Ftp2")

ftp.Hostname = "ftp.something.com"
ftp.Username = "my_login"
ftp.Password = "my_password"

' Connect and login to the FTP server.
success = ftp.Connect()
If (success <> 1) Then
    outFile.WriteLine(ftp.LastErrorText)
    WScript.Quit
End If

' Set the current remote directory to the root of
' the tree to be downloaded.
success = ftp.ChangeRemoteDir("/subDir1")
If (success <> 1) Then
    outFile.WriteLine(ftp.LastErrorText)
    WScript.Quit
End If

' Possible synchronization modes are:
' mode=0: Download all files
' mode=1: Download all files that do not exist on the local filesystem.
' mode=2: Download newer or non-existant files.
' mode=3: Download only newer files. If a file does not already exist on the local filesystem, it is not downloaded from the server..
' mode=5: Download only missing files or files with size differences.
' mode=6: Same as mode 5, but also download newer files.

' Imagine our remote directory tree has these files and directories:

' 	accentedLatin1.txt
' 	accentedUtf8.txt
' 	alice.key
' 	anter_cert.pem
' 	chiliPepper.gif
' 	helloWorld.pdf
' 	abc/chiliPepper.gif
' 	abc/ghk/
' 	data/chiliPepper.gif
' 	data/xyz/dkimHtmlBody.txt
' 	data/xyz/dkimVerifyTest.eml
' 	data/xyz/emailForCreateDsn.eml
' 	text/frenchUtf8.txt
' 	text/helloWorld.txt
' 	text/PolishEmailBody.txt
' 	text/something/

' Only enter remote directories named either "data" or matching "x*"
ftp.SyncMustMatchDir = "data; x*"
mode = 0
success = ftp.SyncLocalTree("c:/temp/subDir1",mode)
If (success <> 1) Then
    outFile.WriteLine(ftp.LastErrorText)
    WScript.Quit
End If

success = ftp.Disconnect()

' Show the files downloaded.
set st = CreateObject("Chilkat.StringTable")
ftp.GetSyncedFiles st

numFiles = st.Count
i = 0

Do While i < numFiles
    outFile.WriteLine(st.StringAt(i))
    i = i + 1
Loop

' Output showing the files downloaded:

' accentedLatin1.txt
' accentedUtf8.txt
' alice.key
' anter_cert.pem
' chiliPepper.gif
' helloWorld.pdf
' data/chiliPepper.gif
' data/xyz/dkimHtmlBody.txt
' data/xyz/dkimVerifyTest.eml
' data/xyz/emailForCreateDsn.eml

outFile.Close