Chilkat Examples

ChilkatHOMEAndroid™Classic ASPCC++C#Mono C#.NET Core C#C# UWP/WinRTDataFlexDelphi ActiveXDelphi DLLVisual FoxProJavaLianjaMFCObjective-CPerlPHP ActiveXPHP ExtensionPowerBuilderPowerShellPureBasicCkPythonChilkat2-PythonRubySQL ServerSwift 2Swift 3/4TclUnicode CUnicode C++Visual Basic 6.0VB.NETVB.NET UWP/WinRTVBScriptXojo PluginNode.jsExcelGo

VBScript Examples

Web API Categories

ASN.1
Amazon Glacier
Amazon S3
Amazon S3 (new)
Amazon SES
Amazon SNS
Amazon SQS
Async
Azure Cloud Storage
Azure Service Bus
Base64
Bounced Email
Box
CAdES
CSR
CSV
Certificates
Compression
DKIM / DomainKey
DSA
Diffie-Hellman
Digital Signatures
Dropbox
Dynamics CRM
ECC
Email Object
Encryption
FTP
FileAccess
Firebase
GMail REST API
Geolocation
Google APIs
Google Calendar
Google Cloud Storage
Google Drive
Google Photos
Google Sheets
Google Tasks
Gzip
HTML-to-XML/Text

HTTP
HTTP Misc
IMAP
JSON
JSON Web Encryption (JWE)
JSON Web Signatures (JWS)
JSON Web Token (JWT)
Java KeyStore (JKS)
MHT / HTML Email
MIME
Microsoft Graph
NTLM
OAuth1
OAuth2
OneDrive
OpenSSL
Outlook
PEM
PFX/P12
POP3
PRNG
REST
REST Misc
RSA
SCP
SFTP
SMTP
SSH
SSH Key
SSH Tunnel
SharePoint
Socket/SSL/TLS
Spider
Stream
Tar Archive
Upload
WebSocket
XAdES
XML
XML Digital Signatures
XMP
Zip
curl

 

 

 

(VBScript) FTP through SSH Tunnel with Dynamic Port Forwarding

Demonstrates how to start a background thread that runs a portable SSH tunnel w/ dynamic port forwarding that the foreground thread can be used for establishing FTP sessions through an SSH tunnel.

Note: Some developers may be accustomed to starting an stunnel.exe proxy from https://www.stunnel.org. The stunnel.exe is not necessary here. Chilkat's background thread fulfills the task of what the external stunnel.exe does. Therefore, your application is self-contained, meaning that it can run anywhere because the SSH tunnel proxy is built-in.

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

'  Starting in v9.5.0.49, all Chilkat classes can be unlocked at once at the beginning of a program
'  by calling UnlockBundle.  It requires a Bundle unlock code.
set chilkatGlob = CreateObject("Chilkat_9_5_0.Global")
success = chilkatGlob.UnlockBundle("Anything for 30-day trial.")
If (success <> 1) Then
    outFile.WriteLine(chilkatGlob.LastErrorText)
    WScript.Quit
End If

'  This example requires Chilkat version 9.5.0.50 or greater.
set tunnel = CreateObject("Chilkat_9_5_0.SshTunnel")

sshHostname = "www.my-ssh-server.com"
sshPort = 22

'  Connect to an SSH server and establish the SSH tunnel:
success = tunnel.Connect(sshHostname,sshPort)
If (success <> 1) Then
    outFile.WriteLine(tunnel.LastErrorText)
    WScript.Quit
End If

'  Authenticate with the SSH server via a login/password
'  or with a public key.
'  This example demonstrates SSH password authentication.
success = tunnel.AuthenticatePw("mySshLogin","mySshPassword")
If (success <> 1) Then
    outFile.WriteLine(tunnel.LastErrorText)
    WScript.Quit
End If

'  Indicate that the background SSH tunnel thread will behave as a SOCKS proxy server
'  with dynamic port forwarding:
tunnel.DynamicPortForwarding = 1

'  We may optionally require that connecting clients authenticate with our SOCKS proxy server.
'  To do this, set an inbound username/password.  Any connecting clients would be required to
'  use SOCKS5 with the correct username/password.
'  If no inbound username/password is set, then our SOCKS proxy server will accept both
'  SOCKS4 and SOCKS5 unauthenticated connections.

tunnel.InboundSocksUsername = "chilkat123"
tunnel.InboundSocksPassword = "password123"

'  Start the listen/accept thread to begin accepting SOCKS proxy client connections.
'  Listen on port 1080.
success = tunnel.BeginAccepting(1080)
If (success <> 1) Then
    outFile.WriteLine(tunnel.LastErrorText)
    WScript.Quit
End If

'  Now that a background thread is running a SOCKS proxy server that forwards connections
'  through an SSH tunnel, it is possible to use any Chilkat implemented protocol that is SOCKS capable,
'  such as HTTP, POP3, SMTP, IMAP, FTP, etc.  The protocol may use SSL/TLS because the SSL/TLS
'  will be passed through the SSH tunnel to the end-destination.  Also, any number of simultaneous
'  connections may be routed through the SSH tunnel.

set ftp = CreateObject("Chilkat_9_5_0.Ftp2")

'  Indicate that the HTTP object is to use our portable SOCKS proxy/SSH tunnel running in our background thread.
ftp.SocksHostname = "localhost"
'  The SocksPort must equal the port passed to BeginAccepting above.
ftp.SocksPort = 1080
ftp.SocksVersion = 5
'  The SOCKS5 login/password set here must equal the InboundSocksUsername/Password set above.
ftp.SocksUsername = "chilkat123"
ftp.SocksPassword = "password123"

'  This is the actual FTP server domain or IP address, and the login/password for the user account on the destination FTP server.
ftp.Hostname = "ftp.someFtpServer.com"
ftp.Username = "myLogin"
ftp.Password = "myPassword"
ftp.AuthTls = 1

'  Connect and login (via the SSH tunnel) to the FTP server.
success = ftp.Connect()
If (success <> 1) Then
    outFile.WriteLine(ftp.LastErrorText)
    WScript.Quit
End If

'  Change to the remote directory where the file is located.
'  This step is only necessary if the file is not in the root directory
'  for the FTP account.
success = ftp.ChangeRemoteDir("junk")
If (success <> 1) Then
    outFile.WriteLine(ftp.LastErrorText)
    WScript.Quit
End If

localFilename = "c:/temp/hamlet.xml"
remoteFilename = "hamlet.xml"

'  Download a file.  (the data connection is also automatically established through the
'  SSH tunnel using dynamic port forwarding..)
success = ftp.GetFile(remoteFilename,localFilename)
If (success <> 1) Then
    outFile.WriteLine(ftp.LastErrorText)
    WScript.Quit
End If

'  The disconnect is disconnecting with the FTP server and closes the SSH tunnel.
'  The background tunnel thread is still running, and may be used for subsequent FTP connections,
'  or even connections for any other purpose, such as HTTP, IMAP, SMTP, POP3, etc.
success = ftp.Disconnect()

'  When the app is finished with the tunnel, it can cleanup..

'  Stop the background listen/accept thread:
waitForThreadExit = 1
success = tunnel.StopAccepting(waitForThreadExit)
If (success <> 1) Then
    outFile.WriteLine(tunnel.LastErrorText)
    WScript.Quit
End If

'  Close the SSH tunnel (would also kick any remaining connected clients).
success = tunnel.CloseTunnel(waitForThreadExit)
If (success <> 1) Then
    outFile.WriteLine(tunnel.LastErrorText)
    WScript.Quit
End If


outFile.Close

 

© 2000-2019 Chilkat Software, Inc. All Rights Reserved.