VBScript

Download Multiple FTP Files by Wildcard (MGET)

Demonstrates the Chilkat Ftp2.MGetFiles method, which downloads files in the current remote directory matching a pattern into a local directory. The first argument is the remote pattern and the second is the local directory. It returns the number of files downloaded, or -1 on failure.

Note: The local paths are relative to the application's current working directory. Absolute paths may also be used. Supply the paths appropriate to your own environment.

Background: This is FTP's mget: fetch everything matching a wildcard in one call rather than looping yourself. It operates on the current remote directory — hence the ChangeRemoteDir first — and does not descend into subdirectories; use DownloadTree for recursive transfers. The count return lets you confirm how many matched, with -1 signaling an outright failure to check separately from a legitimate zero.

Chilkat VBScript Downloads

Download Chilkat for VBScript

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

'  Demonstrates the Ftp2.MGetFiles method, which downloads files in the current remote directory
'  matching a pattern into a local directory.  The 1st argument is the remote pattern and the 2nd
'  is the local directory.  It returns the number of files downloaded, or -1 on failure.

set ftp = CreateObject("Chilkat.Ftp2")

ftp.Hostname = "ftp.example.com"
ftp.Username = "myFtpLogin"

'  Normally you would not hard-code the password in source.  You should instead obtain it
'  from an interactive prompt, environment variable, or a secrets vault.
ftp.Password = "myPassword"

success = ftp.Connect()
If (success = 0) Then
    outFile.WriteLine(ftp.LastErrorText)
    WScript.Quit
End If

success = ftp.ChangeRemoteDir("public_html")
If (success = 0) Then
    outFile.WriteLine(ftp.LastErrorText)
    WScript.Quit
End If

'  Download all .html files from the current remote directory.  Subdirectories are not traversed.
numDownloaded = ftp.MGetFiles("*.html","qa_output/site")
If (numDownloaded < 0) Then
    outFile.WriteLine(ftp.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Downloaded " & numDownloaded & " files.")

success = ftp.Disconnect()
If (success = 0) Then
    outFile.WriteLine(ftp.LastErrorText)
    WScript.Quit
End If


outFile.Close