VBScript

Get an FTP Listing Entry's Owner

Demonstrates the Chilkat Ftp2.GetOwner method, which returns the owner name or identifier of a cached directory-listing entry. The only argument is a zero-based index. The value is empty when a valid entry has no owner metadata.

Background: Owner information appears in Unix-style listings and is useful for auditing or for deciding whether an operation is likely to be permitted. It is not universally available — some servers and listing formats omit it entirely, and it may be a numeric ID rather than a name — so treat an empty result as "not reported" rather than an error.

Chilkat VBScript Downloads

Download Chilkat for VBScript

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

'  Demonstrates the Ftp2.GetOwner method, which returns the owner name or identifier of a cached
'  directory-listing entry.  The only argument is a zero-based index.

set ftp = CreateObject("Chilkat.Ftp2")

ftp.Hostname = "ftp.example.com"
ftp.Username = "myFtpLogin"

'  Normally you would not hard-code the password in source.  You should instead obtain it
'  from an interactive prompt, environment variable, or a secrets vault.
ftp.Password = "myPassword"

success = ftp.Connect()
If (success = 0) Then
    outFile.WriteLine(ftp.LastErrorText)
    WScript.Quit
End If

success = ftp.ChangeRemoteDir("public_html")
If (success = 0) Then
    outFile.WriteLine(ftp.LastErrorText)
    WScript.Quit
End If

'  GetDirCount retrieves the directory listing on the first call and returns the number of
'  entries.  A negative return indicates failure.
n = ftp.GetDirCount()
If (n < 0) Then
    outFile.WriteLine(ftp.LastErrorText)
    WScript.Quit
End If

For i = 0 To n - 1
    name = ftp.GetFilename(i)

    '  The owner is empty when a valid entry has no owner metadata.
    owner = ftp.GetOwner(i)
    outFile.WriteLine(owner & "  " & name)
Next

success = ftp.Disconnect()
If (success = 0) Then
    outFile.WriteLine(ftp.LastErrorText)
    WScript.Quit
End If


outFile.Close