VBScript

Check if an FTP Listing Entry is a Symbolic Link

Demonstrates the Chilkat Ftp2.GetIsSymbolicLink method, which returns whether a cached directory-listing entry is a symbolic link. The only argument is a zero-based index. This information is available only when the server's listing format reports it.

Background: Symbolic links matter because following one can lead outside the expected directory or into a cycle, so recursive operations often need to identify and skip them. Unlike the file/directory distinction, symlink information is not always present — only listing formats that mark links (typically Unix-style LIST output) expose it, and this returns false when the server does not.

Chilkat VBScript Downloads

Download Chilkat for VBScript

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

'  Demonstrates the Ftp2.GetIsSymbolicLink method, which returns whether a cached directory-listing
'  entry is a symbolic link.  The only argument is a zero-based index.  This information is only
'  available when the server's listing format reports it.

set ftp = CreateObject("Chilkat.Ftp2")

ftp.Hostname = "ftp.example.com"
ftp.Username = "myFtpLogin"

'  Normally you would not hard-code the password in source.  You should instead obtain it
'  from an interactive prompt, environment variable, or a secrets vault.
ftp.Password = "myPassword"

success = ftp.Connect()
If (success = 0) Then
    outFile.WriteLine(ftp.LastErrorText)
    WScript.Quit
End If

success = ftp.ChangeRemoteDir("public_html")
If (success = 0) Then
    outFile.WriteLine(ftp.LastErrorText)
    WScript.Quit
End If

'  GetDirCount retrieves the directory listing on the first call and returns the number of
'  entries.  A negative return indicates failure.
n = ftp.GetDirCount()
If (n < 0) Then
    outFile.WriteLine(ftp.LastErrorText)
    WScript.Quit
End If

For i = 0 To n - 1
    name = ftp.GetFilename(i)
    If (ftp.GetIsSymbolicLink(i)) Then
        outFile.WriteLine("[LINK] " & name)
    Else
        outFile.WriteLine("       " & name)
    End If

Next

success = ftp.Disconnect()
If (success = 0) Then
    outFile.WriteLine(ftp.LastErrorText)
    WScript.Quit
End If


outFile.Close