Chilkat Examples

ChilkatHOMEAndroid™Classic ASPCC++C#Mono C#.NET Core C#C# UWP/WinRTDataFlexDelphi ActiveXDelphi DLLVisual FoxProJavaLianjaMFCObjective-CPerlPHP ActiveXPHP ExtensionPowerBuilderPowerShellPureBasicCkPythonChilkat2-PythonRubySQL ServerSwift 2Swift 3/4TclUnicode CUnicode C++Visual Basic 6.0VB.NETVB.NET UWP/WinRTVBScriptXojo PluginNode.jsExcelGo

VBScript Web API Examples

Primary Categories

AWS Translate
Azure Maps
Azure OAuth2
Azure Storage Accounts
CardConnect
Cloudfare
Facebook
GeoOp
Jira
Magento
Microsoft Calendar
Microsoft Group
Microsoft Tasks and Plans

PayPal
Peoplevox
Populi
QuickBooks
SOAP finkok.com
Shopify
Stripe
SugarCRM
Trello
Twitter
VoiceBase
Walmart
Xero
eBay
effectconnect

 

 

 

(VBScript) Read a Single Facebook Post

Demonstrates how to read the contents of a single Facebook post. A post is an individual entry in a profile's feed. The profile could be a user, page, app, or group.

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' This example assumes a previously obtained an access token
set oauth2 = CreateObject("Chilkat_9_5_0.OAuth2")
oauth2.AccessToken = "FACEBOOK-ACCESS-TOKEN"

set rest = CreateObject("Chilkat_9_5_0.Rest")

' Connect to Facebook...
success = rest.Connect("graph.facebook.com",443,1,1)
If (success <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' Provide the authentication credentials (i.e. the access key)
success = rest.SetAuthOAuth2(oauth2)

' This example assumes a post id was already retrieved.
' For example, it could've been retrieved by reading the user's feed:
' See Parsing the Facebook User Feed for code showing how to parse the JSON feed content.

postId = "10224048320139890_10210156138515282"

set sbPath = CreateObject("Chilkat_9_5_0.StringBuilder")
success = sbPath.Append("/v2.7/")
success = sbPath.Append(postId)

' Select the fields we want.
' This example will select almost all the possible fields.
' See https://developers.facebook.com/docs/graph-api/reference/post/
success = rest.AddQueryParam("fields","id,message,created_time,caption,description,from,link,name,object_id,picture,place,privacy,properties,shares,source,status_type,story,targeting,to,type,updated_time,with_tags")

responseJson = rest.FullRequestNoBody("GET",sbPath.GetAsString())
If (rest.LastMethodSuccess <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

set json = CreateObject("Chilkat_9_5_0.JsonObject")
json.EmitCompact = 0
success = json.Load(responseJson)

' Show the JSON in human-readable format.
outFile.WriteLine(json.Emit())

' A sample JSON response is shown here.  
' { 
'   "id": "12345678901234567_12345678900000004",
'   "message": "Ignore my posts -- I'm doing some testing for Facebook related programming...",
'   "created_time": "2016-09-29T20:46:18+0000",
'   "from": { 
'     "name": "John Doe",
'     "id": "12345678901234567"
'   },
'   "link": "https:\/\/www.facebook.com\/photo.php?fbid=10210199026247451&set=a.1237223526054.2038240.1094202869&type=3",
'   "object_id": "10210139026347451",
'   "picture": "https:\/\/scontent.xx.fbcdn.net\/v\/t1.0-9\/14462791_10210199026647451_7830642117574407060_n.jpg?oh=a7f9ed10ce9cd81a82adeb541c60e2e2&oe=58ABB195",
'   "privacy": { 
'     "allow": "",
'     "deny": "",
'     "description": "Public",
'     "friends": "",
'     "value": "EVERYONE"
'   },
'   "status_type": "added_photos",
'   "type": "photo",
'   "updated_time": "2016-09-29T20:46:18+0000"
' }

' This is the code to parse some fields in the JSON response.
outFile.WriteLine("type: " & json.StringOf("type"))
outFile.WriteLine("message: " & json.StringOf("message"))
outFile.WriteLine("id: " & json.StringOf("id"))
outFile.WriteLine("link: " & json.StringOf("link"))
outFile.WriteLine("privacy descripton: " & json.StringOf("privacy.description"))

set dtime = CreateObject("Chilkat_9_5_0.CkDateTime")
bLocalTime = 1
success = dtime.SetFromTimestamp(json.StringOf("created_time"))
' dt is a Chilkat_9_5_0.DtObj
Set dt = dtime.GetDtObj(bLocalTime)
outFile.WriteLine(dt.Month & "/" & dt.Day & "/" & dt.Year & "  " & dt.Hour & ":" & dt.Minute)


outFile.Close

 

© 2000-2019 Chilkat Software, Inc. All Rights Reserved.