VBScript

Example: Http.SetOAuthRsaKey method

Demonstrates the SetOAuthRsaKey method. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

set pfx = CreateObject("Chilkat.Pfx")
success = pfx.LoadPfxFile("qa_data/pfx/MCD_Sandbox_chilkat_iccp_API_Keys/chilkat_iccp-sandbox.p12","keystorepassword")
If (success = 0) Then
    outFile.WriteLine(pfx.LastErrorText)
    WScript.Quit
End If

set privKey = CreateObject("Chilkat.PrivateKey")
success = pfx.PrivateKeyAt(0,privKey)
If (success = 0) Then
    outFile.WriteLine(pfx.LastErrorText)
    WScript.Quit
End If

set http = CreateObject("Chilkat.Http")

' Use OAuth1.0a authentication.
http.OAuth1 = 1

' Use your own consumer key (this is not a valid consumer key)
http.OAuthConsumerKey = "123abc"

http.OAuthSigMethod = "RSA-SHA256"

success = http.SetOAuthRsaKey(privKey)
If (success = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

' Tell Chilkat to automatically calculate and add the oauth_body_hash field when sending the request.
http.OAuthBodyHash = 1

' Send this request to an endpoint at chilkatsoft.com.  The purpose of this example is to show
' how the OAuth1.0a Authorization header is computed and sent by Chilkat.
' The chilkatsoft.com site itself doesn't do OAuth1.  It's just ignoring the Authorization header.
set resp = CreateObject("Chilkat.HttpResponse")
success = http.HttpStr("POST","https://chilkatsoft.com/echo_request_body.asp","<notUsed>123</notUsed>","utf-8","application/xml",resp)
If (success = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

' Examine the request header we just sent..
outFile.WriteLine(http.LastHeader)

' Sample output:

' POST /echo_request_body.asp HTTP/1.1
' Host: chilkatsoft.com
' Accept: */*
' Accept-Encoding: gzip
' Content-Type: application/xml
' Content-Length: 22
' Authorization: OAuth oauth_consumer_key="123abc", oauth_nonce="A2E91C3B53E0BD7FBF71F441336679E358DDCEEE", oauth_body_hash="a5kPTsDwUwmBjC0voNlAAvM6YoaRS5X7sTO49jl3/h8=", oauth_timestamp="1756324932", oauth_signature_method="RSA-SHA256", oauth_version="1.0", oauth_signature="*****"

outFile.Close