VBScript

Example: Http.ResumeDownloadBd method

Demonstrates the ResumeDownloadBd method. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

set http = CreateObject("Chilkat.Http")
http.KeepResponseBody = 1

' To demonstrate resuming a download, we've created a file on the chilkatsoft.com
' web server that contains the first 82,379 bytes of the full  279,658 bytes of the hamlet.xml file.

' We'll first download the partial file, and pretend it was a previous incomplete attempt to download the entire file.
set bd = CreateObject("Chilkat.BinData")
success = http.DownloadBd("https://www.chilkatsoft.com/testData/hamlet_partial.xml",bd)
If (success = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

' Download the remainder of hamlet.xml.
success = http.ResumeDownloadBd("https://www.chilkatsoft.com/testData/hamlet.xml",bd)
statusCode = http.LastStatus
If (success = 0) Then
    If (statusCode = 0) Then
        ' Unable to either send the request or get the response.
        outFile.WriteLine(http.LastErrorText)
    Else
        ' We got a response, but the status code was not in the 200s
        outFile.WriteLine("Response status code: " & statusCode)
        ' Examine the response body.
        outFile.WriteLine("Response body:")
        outFile.WriteLine(http.LastResponseBody)
    End If

    outFile.WriteLine("Download failed.")

Else
    outFile.WriteLine("Download success, response status = " & statusCode)
End If

' The hamlet.xml file should be 279,658 bytes
outFile.WriteLine("size of hamlet.xml: " & bd.NumBytes)

outFile.WriteLine("Success.")

outFile.Close