VBScript

Load .eml and Examine the Structure, Attachments, and Related Items

See more Email Object Examples

Demonstrates how to load examine the MIME structure of a .eml, and also examine the attachment and related item filenames, attached messages, and multipart/report and DSN information. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

emlPath = "C:/AAWorkarea/beatrix/roesner.eml"

set mime = CreateObject("Chilkat.Mime")

success = mime.LoadMimeFile(emlPath)
If (success = 0) Then
    outFile.WriteLine(mime.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("---- MIME structure ----")
outFile.WriteLine(mime.GetStructure("text"))
outFile.WriteLine("------------------------")

set email = CreateObject("Chilkat.Email")
success = email.LoadEml(emlPath)

' Was this a signed and/or encrypted email?
' If so, then loading the .eml automatically unwraps
' (i.e. verifies signatures and decrypts) and the resultant
' email is what existed prior to signing/encrypting.
outFile.WriteLine("Email was Signed: " & email.ReceivedSigned)
outFile.WriteLine("Email was Encrypted: " & email.ReceivedEncrypted)
If (email.ReceivedSigned = 1) Then
    outFile.WriteLine("Signature(s) valid = " & email.SignaturesValid)
End If

If (email.ReceivedEncrypted = 1) Then
    outFile.WriteLine("Decrypted successfully = " & email.Decrypted)
End If

i = 0
numAttach = email.NumAttachments
outFile.WriteLine("Number of attachments = " & numAttach)

Do While i < numAttach
    outFile.WriteLine("---- Attachment " & i)

    ' Examine the filename (if any)
    outFile.WriteLine("filename: " & email.GetAttachmentFilename(i))
    ' Examine the content-ID (if any)
    outFile.WriteLine("Content-ID: " & email.GetAttachmentContentID(i))
    ' Examine the content-type
    outFile.WriteLine("Content-Type: " & email.GetAttachmentContentType(i))
    ' Examine the content-disposition
    outFile.WriteLine("Content-Disposition" & email.GetAttachmentHeader(i,"content-disposition"))
    ' Examine the attachment size:
    outFile.WriteLine("Size (in bytes) of the attachment: " & email.GetAttachmentSize(i))

    i = i + 1
Loop
outFile.WriteLine("--")

' Now for the related items.

' Note: A MIME sub-part can potentially be both a related item AND an attachment.
' The typical case is when the item is contained under the multipart/related enclosure and 
' the item also has a "Content-Disposition" header indicating "attachment".
' The location within multipart/related makes it a "related item", yet the Content-Disposition can also make it semantically an attachment.
' Related items and attachments are not necessarily mutually exclusive.

numRelated = email.NumRelatedItems
outFile.WriteLine("Number of related items = " & numRelated)
i = 0
Do While i < numRelated
    outFile.WriteLine("---- Related Item " & i)

    ' Examine the filename (if any)
    outFile.WriteLine("filename: " & email.GetRelatedFilename(i))
    ' Examine the content-ID (if any)
    outFile.WriteLine("Content-ID: " & email.GetRelatedContentID(i))
    ' Examine the content-type
    outFile.WriteLine("Content-Type: " & email.GetRelatedContentType(i))
    ' Examine the content-location (if any)
    outFile.WriteLine("Content-Location" & email.GetRelatedContentLocation(i))

    i = i + 1
Loop

' The email could also have attached messages.
' An attached message is another email that was attached to this email.
set em = CreateObject("Chilkat.Email")
numAttachedMessages = email.NumAttachedMessages
outFile.WriteLine("Number of attached messages = " & numAttachedMessages)
i = 0
Do While i < numAttachedMessages
    outFile.WriteLine("---- Attached message " & i)

    ' Examine the attached email
    success = email.GetAttachedEmail(i,em)
    outFile.WriteLine("from: " & em.From)
    outFile.WriteLine("subject: " & em.Subject)
    i = i + 1
Loop

' An email could also be a multipart/report email. 
' This is a DSN (Delivery Status Notification)
' The NumReports property indicates how many "reports" exist.
numReports = email.NumReports
outFile.WriteLine("Number of reports = " & numReports)
i = 0
Do While i < numReports
    outFile.WriteLine("---- Report " & i)
    ' Get the raw report data...
    outFile.WriteLine(email.GetReport(i))
    i = i + 1
Loop

' If the email is a multipart/report, then the information
' from the message/delivery-status part of the email can be retrieved:
If (email.IsMultipartReport() = 1) Then

    outFile.WriteLine("--- Delivery Status Information:")
    outFile.WriteLine("Status: " & email.GetDeliveryStatusInfo("Status"))
    outFile.WriteLine("Action: " & email.GetDeliveryStatusInfo("Action"))
    outFile.WriteLine("Reporting-MTA: " & email.GetDeliveryStatusInfo("Reporting-MTA"))

    set jsonDsnInfo = CreateObject("Chilkat.JsonObject")
    success = email.GetDsnInfo(jsonDsnInfo)
    jsonDsnInfo.EmitCompact = 0
    outFile.WriteLine(jsonDsnInfo.Emit())
End If


outFile.Close