(VBScript) How to Generate an Elliptic Curve Shared Secret

Demonstrates how to generate an ECC (Elliptic Curve Cryptography) shared secret. Imagine a cilent has one ECC private key, the server has another. A shared secret is computed by each side providing it's public key to the other. The private keys are kept private.

Note: This example requires Chilkat v11.0.0 or greater.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' This example includes both client-side and server-side code.
' Each code segment is marked as client-side or server-side.
' Imagine these segments are running on separate computers...

' -----------------------------------------------------------------
' (Client-Side) Generate an ECC key, save the public part to a file.
' -----------------------------------------------------------------
set prngClient = CreateObject("Chilkat.Prng")
set eccClient = CreateObject("Chilkat.Ecc")
set privKeyClient = CreateObject("Chilkat.PrivateKey")
success = eccClient.GenKey("secp256r1",prngClient,privKeyClient)
If (success = 0) Then
    outFile.WriteLine(eccClient.LastErrorText)
    WScript.Quit
End If

set pubKeyClient = CreateObject("Chilkat.PublicKey")
success = privKeyClient.ToPublicKey(pubKeyClient)
success = pubKeyClient.SavePemFile(0,"qa_output/eccClientPub.pem")

' -----------------------------------------------------------------
' (Server-Side) Generate an ECC key, save the public part to a file.
' -----------------------------------------------------------------
set prngServer = CreateObject("Chilkat.Prng")
set eccServer = CreateObject("Chilkat.Ecc")
set privKeyServer = CreateObject("Chilkat.PrivateKey")
success = eccServer.GenKey("secp256r1",prngServer,privKeyServer)

set pubKeyServer = CreateObject("Chilkat.PublicKey")
success = privKeyServer.ToPublicKey(pubKeyServer)
success = pubKeyServer.SavePemFile(0,"qa_output/eccServerPub.pem")

' -----------------------------------------------------------------
' (Client-Side) Generate the shared secret using our private key, and the other's public key.
' -----------------------------------------------------------------

' Imagine that the server sent the public key PEM to the client.
' (This is simulated by loading the server's public key from the file.
set pubKeyFromServer = CreateObject("Chilkat.PublicKey")
success = pubKeyFromServer.LoadFromFile("qa_output/eccServerPub.pem")
sharedSecret1 = eccClient.SharedSecretENC(privKeyClient,pubKeyFromServer,"base64")

' -----------------------------------------------------------------
' (Server-Side) Generate the shared secret using our private key, and the other's public key.
' -----------------------------------------------------------------

' Imagine that the client sent the public key PEM to the server.
' (This is simulated by loading the client's public key from the file.
set pubKeyFromClient = CreateObject("Chilkat.PublicKey")
success = pubKeyFromClient.LoadFromFile("qa_output/eccClientPub.pem")
sharedSecret2 = eccServer.SharedSecretENC(privKeyServer,pubKeyFromClient,"base64")

' ---------------------------------------------------------
' Examine the shared secrets.  They should be the same.
' Both sides now have a secret that only they know.
' ---------------------------------------------------------
outFile.WriteLine(sharedSecret1)
outFile.WriteLine(sharedSecret2)

outFile.Close