VBScript

Transition from Compression.BeginCompressBytes to FirstChunk/LastChunk

Provides instructions for replacing deprecated BeginCompressBytes method calls with using FirstChunk and LastChunk properties. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

set facSrc = CreateObject("Chilkat.FileAccess")
set facDest = CreateObject("Chilkat.FileAccess")

' Open a large binary file for reading.
success = facSrc.OpenForRead("qa_data/bmp/big.bmp")
If (success = 0) Then
    outFile.WriteLine(facSrc.LastErrorText)
    WScript.Quit
End If

' If we compress in 64K chunks, find out how many blocks there will be.
blockSize = 65536
numBlocks = facSrc.GetNumBlocks(blockSize)

' Open an output file for the compressed data.
success = facDest.OpenForWrite("c:/temp/qa_output/compressedBmp.dat")
If (success = 0) Then
    outFile.WriteLine(facDest.LastErrorText)
    WScript.Quit
End If

set compress = CreateObject("Chilkat.Compression")
compress.Algorithm = "deflate"

' ----------------------------------------------------------------------------------
' This is the deprecated way of compressing in chunks using Begin/More/End methods..
' ----------------------------------------------------------------------------------
i = 0
Do While i < numBlocks
    fileBytes = facSrc.ReadBlock(i,blockSize)
    If (i = 0) Then
        compressedBytes = compress.BeginCompressBytes(fileBytes)
    Else
        compressedBytes = compress.MoreCompressBytes(fileBytes)
    End If

    success = facDest.FileWrite(compressedBytes)

    i = i + 1
Loop

' At the very end, flush any remaining compressed bytes, if any.
compressedBytes = compress.EndCompressBytes()
success = facDest.FileWrite(compressedBytes)

facSrc.FileClose 
facDest.FileClose 

outFile.WriteLine("Finished compressing file.")

' ----------------------------------------------------------------------------------
' This is new way of compressing in chunks using FirstChunk and LastChunk properties
' ----------------------------------------------------------------------------------

success = facSrc.OpenForRead("qa_data/bmp/big.bmp")
If (success = 0) Then
    outFile.WriteLine(facSrc.LastErrorText)
    WScript.Quit
End If

success = facDest.OpenForWrite("c:/temp/qa_output/compressedBmp2.dat")
If (success = 0) Then
    outFile.WriteLine(facDest.LastErrorText)
    WScript.Quit
End If

' Assuming numBlocks > 1
compress.FirstChunk = 1
compress.LastChunk = 0

i = 0
Do While i < numBlocks
    fileBytes = facSrc.ReadBlock(i,blockSize)
    compressedBytes = compress.CompressBytes(fileBytes)

    success = facDest.FileWrite(compressedBytes)

    i = i + 1

    compress.FirstChunk = 0
    If (i = (numBlocks - 1)) Then
        compress.LastChunk = 1
    End If

Loop

facSrc.FileClose 
facDest.FileClose 

outFile.WriteLine("Finished compressing file 2.")

outFile.Close