(VBScript) Decompress Large Binary File in Blocks

Decompresses a large binary file in blocks.

Note: This example requires Chilkat v11.0.0 or greater.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set facSrc = CreateObject("Chilkat.FileAccess")
set facDest = CreateObject("Chilkat.FileAccess")

' Open a previously compressed file for decompressing.
' See Compress Large File in Blocks

success = facSrc.OpenForRead("c:/temp/qa_output/compressedBmp.dat")
If (success = 0) Then
    outFile.WriteLine(facSrc.LastErrorText)
    WScript.Quit
End If

' If we compress in 32K chunks, find out how many blocks there will be.
blockSize = 32768
numBlocks = facSrc.GetNumBlocks(blockSize)

' Open an output file for the decompressed data.
success = facDest.OpenForWrite("c:/temp/qa_output/decompressed.bmp")
If (success = 0) Then
    outFile.WriteLine(facDest.LastErrorText)
    WScript.Quit
End If

set compress = CreateObject("Chilkat.Compression")
compress.Algorithm = "deflate"

' Assuming numBlocks > 1
compress.FirstChunk = 1
compress.LastChunk = 0

i = 0
Do While i < numBlocks
    compressedBytes = facSrc.ReadBlock(i,blockSize)

    decompressedBytes = compress.DecompressBytes(compressedBytes)
    success = facDest.FileWrite(decompressedBytes)

    i = i + 1

    compress.FirstChunk = 0
    If (i = (numBlocks - 1)) Then
        compress.LastChunk = 1
    End If

Loop

facSrc.FileClose 
facDest.FileClose 

outFile.WriteLine("Finished decompressing file.")

outFile.Close