(VBScript) Verify Opaque Signature and Retrieve Signing Certificates

Demonstrates how to verify a PCKS7 opaque digital signature (signed data), extract the original file/data, and then extract the certificate(s) that were used to sign.

Note: This example requires Chilkat v11.0.0 or greater.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set crypt = CreateObject("Chilkat.Crypt2")

' Verify a PKCS7 signed-data (opaque signature) file and extract the original content to a file.
success = crypt.VerifyP7M("qa_data/p7m/opaqueSig.p7","qa_output/originalData.dat")
If (success = 0) Then
    outFile.WriteLine(crypt.LastErrorText)
    WScript.Quit
End If

' Alternatively, we can do it in memory...
set binData = CreateObject("Chilkat.BinData")
success = binData.LoadFile("qa_data/p7m/opaqueSig.p7")
' Your app should check for success, but we'll skip the check for brevity..

' If verified, the signature is unwrapped and binData is replaced with the original data that was signed.
success = crypt.OpaqueVerifyBd(binData)
If (success = 0) Then
    outFile.WriteLine(crypt.LastErrorText)
    WScript.Quit
End If

' For our testing, we signed some text, so we can get it from the binData..
outFile.WriteLine("Original Data:")
outFile.WriteLine(binData.GetString("utf-8"))

' After any method call that verifies a signature, the crypt object will contain the certificate(s)
' that were used for signing (assuming the X.509 certs were available in the signature, which is typically the case).

' Get each signing certificate, and build the certificate chain for each.
set cert = CreateObject("Chilkat.Cert")
set certChain = CreateObject("Chilkat.CertChain")
numCerts = crypt.NumSignerCerts
i = 0
Do While i < numCerts
    success = crypt.LastSignerCert(i,cert)
    outFile.WriteLine(cert.SubjectDN)

    success = cert.BuildCertChain(certChain)
    If (success = 0) Then
        outFile.WriteLine(cert.LastErrorText)
        WScript.Quit
    End If

    i = i + 1
Loop

outFile.Close