VBScript

CMS Sign Hash

Demonstrates how to use the SignHashENC method to sign a pre-computed hash. This method creates a CMS signature (PKCS7 detached signature).

This example requires Chilkat v9.5.0.90 or later.

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set crypt = CreateObject("Chilkat.Crypt2")

' Create the hash to be signed...
crypt.HashAlgorithm = "sha256"
crypt.EncodingMode = "base64"
crypt.Charset = "utf-8"
' Create the SHA256 hash of a string using the utf-8 byte representation.
' Return the hash as base64.
base64Hash = crypt.HashStringENC("This is the string to be hashed")

' Load a certificate for signing.
set cert = CreateObject("Chilkat.Cert")
success = cert.LoadPfxFile("qa_data/pfx/cert_test123.pfx","test123")
If (success = 0) Then
    outFile.WriteLine(cert.LastErrorText)
    WScript.Quit
End If

success = crypt.SetSigningCert(cert)

' Sign the hash to create a base64 CMS signature (which does not contain the original data).
' We can get the signature in a single line of base64 by specifying "base64", or 
' we can get multi-line base64 by specifying "base64_mime".
crypt.EncodingMode = "base64_mime"
base64CmsSig = crypt.SignHashENC(base64Hash,"sha256","base64")
If (crypt.LastMethodSuccess = 0) Then
    outFile.WriteLine(crypt.LastErrorText)
    WScript.Quit
End If

' Note: In the above call to SignHashENC, the encoding of the returned CMS signature is specified by the EncodingMode property.
' However, the encoding of the passed-in hash is indicated by the 3rd argument.

outFile.WriteLine("CMS Signature: " & base64CmsSig)

outFile.Close