(VBScript) Base64url Encoding

Base64url encoding is identical to base64 encoding except it uses non-reserved URL characters (e.g. '–' is used instead of '+', and '_' is used instead of '/') and it omits the padding characters. Chilkat adds support for "base64url" in version 9.5.0.56. (To be released Q1 2016.) The list of binary encodings supported by Chilkat are documented at Chilkat Binary Encodings For any supported encoding, such as base64, hex, url, quoted-printable, modbase64, base64url, etc., the encoding name may be used in any "EncodingMode" property or in any method argument that specifies a binary encoding. (Please note that a "binary encoding" is different than a "character encoding". Character encodings supported by Chilkat are listed at Chilkat Character Encodings.) This example demonstrates using base64url encoding by setting the RSA object's EncodingMode property equal to "base64url".

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Create an instance of a certificate store object, load a PFX file,
' locate the certificate we need, and use it for signing.
' (a PFX file may contain more than one certificate.)
set certStore = CreateObject("Chilkat_9_5_0.CertStore")

' The 1st argument is the filename, the 2nd arg is the 
' PFX file's password:
success = certStore.LoadPfxFile("chilkat.pfx","test")
If (success <> 1) Then
    outFile.WriteLine(certStore.LastErrorText)
    WScript.Quit
End If

' cert is a Chilkat_9_5_0.Cert
Set cert = certStore.FindCertBySubject("Chilkat Software, Inc.")
If (certStore.LastMethodSuccess = 0) Then
    outFile.WriteLine(certStore.LastErrorText)
    WScript.Quit
End If

' pkey is a Chilkat_9_5_0.PrivateKey
Set pkey = cert.ExportPrivateKey()
If (cert.LastMethodSuccess = 0) Then
    outFile.WriteLine(cert.LastErrorText)

    WScript.Quit
End If

' Get the private key in XML format:
pkeyXml = pkey.GetXml()

set rsa = CreateObject("Chilkat_9_5_0.Rsa")

' Import the private key into the RSA component:
success = rsa.ImportPrivateKey(pkeyXml)
If (success <> 1) Then
    outFile.WriteLine(rsa.LastErrorText)

    WScript.Quit
End If

' This example will sign a string, and receive the signature
' as a base64url encoded string.  Therefore, set the encoding mode
' to "base64url":
rsa.EncodingMode = "base64url"
rsa.LittleEndian = 0

strData = "This is the string to be signed."
strSig = rsa.SignStringENC(strData,"sha256")

outFile.WriteLine(strSig)

outFile.Close