VBScript

Convert ASN.1 to/from Binary DER, XML, and Base64

Demonstrates how to convert ASN.1 from and to any of the following formats: binary DER, Base64, and XML. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

set asn = CreateObject("Chilkat.Asn")

' Begin with loading ASN.1 from a binary DER/BER format file.
success = asn.LoadBinaryFile("/Users/chilkat/testData/p7b/test.p7b")
If (success <> 1) Then
    outFile.WriteLine(asn.LastErrorText)
    WScript.Quit
End If

' Convert ASN.1 to XML:
strXml = asn.AsnToXml()
If (asn.LastMethodSuccess <> 1) Then
    outFile.WriteLine(asn.LastErrorText)
    WScript.Quit
End If

' The XML returned by AsnToXml will be compact and not pretty-formatted.
' Use Chilkat XML to format the XML better:
set xml = CreateObject("Chilkat.Xml")
success = xml.LoadXml(strXml)
' Assuming success for this example..
' This is formatted better for human viewing:
outFile.WriteLine(xml.GetXml())

' Now get the ASN.1 in base64 format.  Any encoding supported
' by Chilkat can be passed, such as "hex", "uu", "quoted-printable", "base32", "modbase64", etc.
strBase64 = asn.GetEncodedDer("base64")

' Load the ASN.1 from XML:
set asn2 = CreateObject("Chilkat.Asn")
success = asn2.LoadAsnXml(xml.GetXml())
If (success <> 1) Then
    outFile.WriteLine(asn2.LastErrorText)
    WScript.Quit
End If

' Load the ASN.1 from an encoded string, such as base64:
set asn3 = CreateObject("Chilkat.Asn")
success = asn3.LoadEncoded(strBase64,"base64")
If (success <> 1) Then
    outFile.WriteLine(asn3.LastErrorText)
    WScript.Quit
End If


outFile.Close