VBScript
XAdES XML Signature using ARSS (Aruba Remote Signing Service)

Demonstrates how to sign XML using ARSS (Aruba Remote Signing Service).
Chilkat VBScript Downloads

VBScript
Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' --------------------------------------------------------------------------------
' Also see Chilkat's Online WSDL Code Generator
' to generate code and SOAP Request and Response XML for each operation in a WSDL.
' --------------------------------------------------------------------------------

' Create the XML to be signed.
set sbXml = CreateObject("Chilkat.StringBuilder")

bCrlf = 1
success = sbXml.AppendLine("<?xml version=""1.0"" encoding=""UTF-8"" standalone=""no"" ?>",bCrlf)
success = sbXml.AppendLine("<SOAP-ENV:Envelope xmlns:SOAP-ENV=""http://schemas.xmlsoap.org/soap/envelope/"">",bCrlf)
success = sbXml.AppendLine("    <SOAP-ENV:Header>",bCrlf)
success = sbXml.AppendLine("        <wsse:Security xmlns:wsse=""http://docs.oasis-open.org/wss/2004/01/oasis-200401-wss-wssecurity-secext-1.0.xsd"" SOAP-ENV:mustUnderstand=""1""></wsse:Security>",bCrlf)
success = sbXml.AppendLine("    </SOAP-ENV:Header>",bCrlf)
success = sbXml.AppendLine("    <SOAP-ENV:Body xmlns:SOAP-SEC=""http://schemas.xmlsoap.org/soap/security/2000-12"" SOAP-SEC:id=""Body"">",bCrlf)
success = sbXml.AppendLine("        <z:FooBar xmlns:z=""http://example.com"" />",bCrlf)
success = sbXml.AppendLine("    </SOAP-ENV:Body>",bCrlf)
success = sbXml.AppendLine("</SOAP-ENV:Envelope>",bCrlf)

' Specify the signing certificate and the ARSS credentials

' Load the certificate used for signing.  The certificate's private key is stored on 
' the Aruba.it server and the signing will happen remotely using the
' ARSS (Aruba Remote Signing Service).
' However, we still need the certificate locally (without private key).
set cert = CreateObject("Chilkat.Cert")
success = cert.LoadFromFile("qa_data/certs/myCert.cer")
If (success = 0) Then
    outFile.WriteLine(cert.LastErrorText)
    WScript.Quit
End If

' To sign using the Aruba Remote Signing Service, 
' add the following lines of code to specify your authentication credentials,
' and the ID of the certificate w/ private key on the server to be used.
set jsonArss = CreateObject("Chilkat.JsonObject")

' Set the "service" equal to "ARSS" to tell Chilkat to use ARSS for signing.
success = jsonArss.UpdateString("service","ARSS")
' Specify the certificate ID, such as "AS0"
' This certificate should match the certificate loaded in the above code.
success = jsonArss.UpdateString("certID","YOUR_ARSS_CERT_ID")
success = jsonArss.UpdateString("otpPwd","YOUR_OTP_PWD")

' Specifies the OTP authentication environment.
' 
' Common values are:
'   "demoprod" - Demo/Test environment
'   "prod"     - Production environment
' 
' This value is sent to the ARSS service and determines how the OTP
' authentication is validated.  The correct value depends on the type
' of Aruba account and environment that has been provisioned.
' 
' If signing fails with an authentication-related error, verify that
' the typeOtpAuth value matches the environment associated with the
' ARSS account credentials being used.
success = jsonArss.UpdateString("typeOtpAuth","demoprod")

success = jsonArss.UpdateString("user","YOUR_ARSS_USERNAME")
success = jsonArss.UpdateString("userPWD","YOUR_ARSS_PASSWORD")

' The "endpoint" can be specified starting in Chilkat v11.5.0
success = jsonArss.UpdateString("endpoint","https://app1.firma-remota.it/ArubaSignerService/webresources/signerservice")

success = cert.SetCloudSigner(jsonArss)

' Prepare for signing...
set gen = CreateObject("Chilkat.XmlDSigGen")

' Indicate where the Signature will be inserted.
gen.SigLocation = "SOAP-ENV:Envelope|SOAP-ENV:Header|wsse:Security"

' Add a reference to the fragment of the XML to be signed.

' Note: "Body" refers to the XML element having an "id" equal to "Body", where "id" is case insensitive
' and where any namespace might qualify the attribute.  In this case, the SOAP-ENV:Body fragment is signed
' NOT because the tag = "Body", but because it has SOAP-SEC:id="Body"
success = gen.AddSameDocRef("Body","sha1","EXCL_C14N","","")

' (You can read about the SignedInfoPrefixList in the online reference documentation.  It's optional..)
gen.SignedInfoPrefixList = "wsse SOAP-ENV"

gen.KeyInfoType = "X509Data"
gen.X509Type = "IssuerSerial"

bUsePrivateKey = 1
success = gen.SetX509Cert(cert,bUsePrivateKey)
If (success = 0) Then
    outFile.WriteLine(gen.LastErrorText)
    WScript.Quit
End If

' Everything's specified.  Now create and insert the Signature
' (The actual signing of the hash will happen on the Aruba server.)
success = gen.CreateXmlDSigSb(sbXml)
If (success = 0) Then
    outFile.WriteLine(gen.LastErrorText)
    WScript.Quit
End If

' Examine the XML with the digital signature inserted
outFile.WriteLine(sbXml.GetAsString())

outFile.Close