VB.NET

SSH Tunnel Static (Fixed-Destination) Port Forwarding

Demonstrates fixed-destination port forwarding with the DestHostname, DestPort, ListenBindIpAddress, and ListenPort properties. Every local connection accepted by the listener is forwarded to the same fixed destination through the SSH server.

Background: This is the classic ssh -L scenario: expose a single remote service — a database, an internal web app — at a local port. Binding the listener to 127.0.0.1 keeps the tunnel private to the local machine, whereas 0.0.0.0 would let other hosts route through it. Passing 0 to BeginAccepting lets the OS pick a free port, which ListenPort then reports — handy when a fixed port might already be in use.

Chilkat VB.NET Downloads

Download Chilkat for VB.NET

VB.NET

Dim success As Boolean = False

'  Demonstrates fixed-destination (static) port forwarding with the SshTunnel properties
'  DestHostname, DestPort, ListenBindIpAddress, and ListenPort.
'  
'  Every local connection accepted by the listener is forwarded to the same fixed destination
'  through the SSH server.

Dim tunnel As New Chilkat.SshTunnel

'  The fixed destination that accepted connections are forwarded to.
tunnel.DestHostname = "db.internal.example.com"
tunnel.DestPort = 5432

'  Bind the listener to loopback so only local processes can use the tunnel.  Use "0.0.0.0" to
'  accept connections from other machines (less secure).
tunnel.ListenBindIpAddress = "127.0.0.1"

Dim sshPort As Integer = 22
success = tunnel.Connect("ssh.example.com",sshPort)
If (success = False) Then
    Debug.WriteLine(tunnel.LastErrorText)
    Exit Sub
End If


'  Normally you would not hard-code the password in source.  You should instead obtain it
'  from an interactive prompt, environment variable, or a secrets vault.
Dim password As String = "mySshPassword"

success = tunnel.AuthenticatePw("mySshLogin",password)
If (success = False) Then
    Debug.WriteLine(tunnel.LastErrorText)
    Exit Sub
End If


'  Pass 0 to let the operating system choose an available port.  After BeginAccepting succeeds,
'  ListenPort contains the actual port that was bound.
success = tunnel.BeginAccepting(0)
If (success = False) Then
    Debug.WriteLine(tunnel.LastErrorText)
    Exit Sub
End If

Debug.WriteLine("Listening on 127.0.0.1 port " & tunnel.ListenPort)

'  Applications now connect to 127.0.0.1:ListenPort as if it were the database server.

Dim waitForThreadExit As Boolean = True
success = tunnel.CloseTunnel(waitForThreadExit)
If (success = False) Then
    Debug.WriteLine(tunnel.LastErrorText)
    Exit Sub
End If