VB.NET

REST Upload Bandwidth Throttle

See more REST Examples

Demonstrates how to use upload bandwidth throttling with the REST API. This example will upload a file to Drobox using a file stream, with a limit on the bandwidth that can be used for the transfer. VB.NET

Dim success As Boolean = False

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' A Dropbox access token should have been previously obtained.
' Dropbox access tokens do not expire.
' See Dropbox Access Token.

' To use bandwidth throttling, the connection should be made using the socket API.
' This provides numerous properties to customize the connection, such as
' BandwidthThrottleDown, BandwidthThrottleUp, ClientIpAddress, ClintPort, Http Proxy,
' KeepAlive, PreferIpv6, RequireSslCertVerify, SoRcvBuf, SoSndBuf, SoReuseAddr,
' SOCKS proxy, TcpNoSDelay, TlsPinSet, TlsCipherSuite, SslAllowedCiphers, etc.

Dim socket As New Chilkat.Socket
Dim maxWaitMs As Integer = 5000
success = socket.Connect("content.dropboxapi.com",443,True,maxWaitMs)
If (success <> True) Then
    Debug.WriteLine(socket.LastErrorText)
    Debug.WriteLine("Connect Fail Reason: " & socket.ConnectFailReason)
    Exit Sub
End If


' Set the upload bandwidth throttle rate to 50000 bytes per second.
socket.BandwidthThrottleUp = 50000

Dim rest As New Chilkat.Rest

' Tell the REST object to use the connected socket.
rest.UseConnection(socket,True)

' The remainder of this example is identical to the example at:
' Dropbox File Stream Upload.

' Add request headers.
rest.AddHeader("Content-Type","application/octet-stream")
rest.AddHeader("Authorization","Bearer DROPBOX_ACCESS_TOKEN")

' The upload "parameters" contained in JSON passed in an HTTP request header.
' This is the JSON to be added in this example:
' { 
'    "path": "/Homework/lit/hamlet.xml",
'    "mode": "add",
'    "autorename": true,
'    "mute": false
' }

Dim json As New Chilkat.JsonObject
json.AppendString("path","/Homework/lit/hamlet.xml")
json.AppendString("mode","add")
json.AppendBool("autorename",True)
json.AppendBool("mute",False)
rest.AddHeader("Dropbox-API-Arg",json.Emit())

' Almost ready to go...
' Let's setup a file stream to point to a file.
Dim fileStream As New Chilkat.Stream
fileStream.SourceFile = "qa_data/xml/hamlet.xml"

' Do the upload.  The URL is https://content.dropboxapi.com/2/files/upload.
' We already connected to content.dropboxapi.com using TLS (i.e. HTTPS),
' so now we only need to specify the path "/2/files/upload".

' Note: The file is streamed directly from disk.  (The entire
' file will not be loaded into memory.)
Dim responseStr As String = rest.FullRequestStream("POST","/2/files/upload",fileStream)
If (rest.LastMethodSuccess = False) Then
    Debug.WriteLine(rest.LastErrorText)
    Exit Sub
End If


' When successful, Dropbox responds with a 200 response code.
If (rest.ResponseStatusCode <> 200) Then
    ' Examine the request/response to see what happened.
    Debug.WriteLine("response status code = " & rest.ResponseStatusCode)
    Debug.WriteLine("response status text = " & rest.ResponseStatusText)
    Debug.WriteLine("response header: " & rest.ResponseHeader)
    Debug.WriteLine("response body (if any): " & responseStr)
    Debug.WriteLine("---")
    Debug.WriteLine("LastRequestStartLine: " & rest.LastRequestStartLine)
    Debug.WriteLine("LastRequestHeader: " & rest.LastRequestHeader)
    Exit Sub
End If


' The response is JSON.
Dim jsonResp As New Chilkat.JsonObject
jsonResp.EmitCompact = False
jsonResp.Load(responseStr)

' Show the JSON response.
Debug.WriteLine(jsonResp.Emit())

' Returns JSON that looks like this:
' { 
'   "name": "hamlet.xml",
'   "path_lower": "/homework/lit/hamlet.xml",
'   "path_display": "/Homework/lit/hamlet.xml",
'   "id": "id:74FkdeNuyKAAAAAAAAAAAQ",
'   "client_modified": "2016-06-02T23:19:00Z",
'   "server_modified": "2016-06-02T23:19:00Z",
'   "rev": "9482db15f",
'   "size": 279658
' }

' Sample code to get data from the JSON response:
Dim size As Integer = jsonResp.IntOf("size")
Debug.WriteLine("size = " & size)

Dim rev As String = jsonResp.StringOf("rev")
Debug.WriteLine("rev = " & rev)

Dim clientModified As String = jsonResp.StringOf("client_modified")
Dim ckdt As New Chilkat.CkDateTime
ckdt.SetFromTimestamp(clientModified)
Dim bLocalTime As Boolean = True
Dim dt As New Chilkat.DtObj
ckdt.ToDtObj(bLocalTime,dt)

Debug.WriteLine(dt.Day & "/" & dt.Month & "/" & dt.Year & " " & dt.Hour & ":" & dt.Minute)