VB.NET

JWE using PBES2 Key Wrapping

See more JSON Web Encryption (JWE) Examples

Demonstrates how to create and decrypt a JWE that using PBES2 key wrapping.

This example demonstrates PBES2 with HMAC SHA-256 and A128KW wrapping. It is also possible to do the following by simply changing the "alg" parameter:

• PBES2 with HMAC SHA-384 and A192KW wrapping
• PBES2 with HMAC SHA-512 and A256KW wrapping

Note: This example requires Chilkat v9.5.0.66 or greater.

VB.NET

Dim success As Boolean = False

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Note: This example requires Chilkat v9.5.0.66 or greater.

Dim plaintext As String = "Live long and prosper."

Dim jwe As New Chilkat.Jwe

' First build the JWE Protected Header..
Dim jweProtHdr As New Chilkat.JsonObject
jweProtHdr.AppendString("alg","PBES2-HS256+A128KW")
jweProtHdr.AppendString("enc","A128GCM")

' PBES2 requires two additional parameters:
' 1) A random salt parameter ("p2s") containing 8 or more bytes in base64url format.
' 2) An iteration count parameter ("p2c").  A minimum count of 1000 is recommended.
'    The iteration count is intended to make the PBES2 computation more expensive (time consuming)
'    to prevent brute-force attacks.
Dim prng As New Chilkat.Prng
jweProtHdr.AppendString("p2s",prng.GenRandom(16,"base64url"))
jweProtHdr.AppendString("p2c","1000")

Debug.WriteLine("JWE Protected Header: " & jweProtHdr.Emit())
Debug.WriteLine("--")

' Don't forget to actually provide the protected header to the JWE object:
jwe.SetProtectedHeader(jweProtHdr)

' Set the PBES2 password
Dim recipientIndex As Integer = 0
jwe.SetPassword(recipientIndex,"top secret")

' Encrypt and return the JWE:
Dim strJwe As String = jwe.Encrypt(plaintext,"utf-8")
If (jwe.LastMethodSuccess <> True) Then
    Debug.WriteLine(jwe.LastErrorText)
    Exit Sub
End If


' Show the JWE we just created:
Debug.WriteLine(strJwe)

' Decrypt the JWE.
Dim jwe2 As New Chilkat.Jwe
success = jwe2.LoadJwe(strJwe)
If (success <> True) Then
    Debug.WriteLine(jwe2.LastErrorText)
    Exit Sub
End If

' Set the PBES2 password
jwe2.SetPassword(recipientIndex,"top secret")

' Decrypt.
Dim originalPlaintext As String = jwe2.Decrypt(0,"utf-8")
If (jwe2.LastMethodSuccess <> True) Then
    Debug.WriteLine(jwe2.LastErrorText)
    Exit Sub
End If


Debug.WriteLine("original text: ")
Debug.WriteLine(originalPlaintext)

' Sample output:

' JWE Protected Header: {"alg":"PBES2-HS256+A128KW","enc":"A128GCM","p2s":"z39rTEfRy1T1Yn_D1mZRlg","p2c":"1000"}
' --
' eyJhbGciOiJQQkVTMi1IUzI1NitBMTI4S1ciLCJlbmMiOiJBMTI4R0NNIiwicDJzIjoiejM5clRFZlJ5MVQxWW5fRDFtWlJsZyIsInAyYyI6IjEwMDAifQ.koYt6PrFmYwcwdcT7ZcvXHA1d-Xez5h4.luGlbvEnZp-7IsBOj42Yhw.YMTcfLf8Qe4zazozGV2OAu3cUdQ8Kg.rWub47ESWkc6IqZJTvSTmg
' original text: 
' Live long and prosper.