Decrypt a JWE to a String

See more JSON Web Encryption (JWE) Examples

Demonstrates Jwe.Decrypt, which decrypts a recipient of a loaded JWE and returns the plaintext, decoded using the given charset. Before decrypting, the example inspects the JWE protected header and, under application policy, accepts only permitted algorithms and selects an acceptable recipient.

Dim success As Boolean = False

Dim jwe As New Chilkat.Jwe

'  Load the JWE compact serialization to be decrypted.
Dim jweCompact As String = "eyJhbGciOiJBMjU2S1ciLCJlbmMiOiJBMjU2R0NNIn0.<...>.<iv>.<ciphertext>.<tag>"
success = jwe.LoadJwe(jweCompact)
If (success = False) Then
    Debug.WriteLine(jwe.LastErrorText)
    Exit Sub
End If


'  Application policy: before decrypting, inspect the JWE header and accept only algorithms the
'  application trusts.  Never assume the algorithms in a received JWE are safe -- a sender could
'  specify a weak or unexpected algorithm.
Dim protHeader As New Chilkat.JsonObject
success = jwe.GetProtectedHeader(protHeader)
If (success = False) Then
    Debug.WriteLine(jwe.LastErrorText)
    Exit Sub
End If


'  Read the alg (key-management) and enc (content-encryption) header values into StringBuilder
'  objects so they can be compared.
Dim sbAlg As New Chilkat.StringBuilder
success = protHeader.StringOfSb("alg",sbAlg)
If (success = False) Then
    Debug.WriteLine(protHeader.LastErrorText)
    Exit Sub
End If

Dim sbEnc As New Chilkat.StringBuilder
success = protHeader.StringOfSb("enc",sbEnc)
If (success = False) Then
    Debug.WriteLine(protHeader.LastErrorText)
    Exit Sub
End If

Debug.WriteLine("JWE algorithms: alg=" & sbAlg.GetAsString() & " enc=" & sbEnc.GetAsString())

'  Enforce an allowlist of acceptable algorithms.  Reject anything not permitted by policy.  String
'  values are compared using StringBuilder.ContentsEqual.
Dim bCaseSensitive As Boolean = True
If (sbAlg.ContentsEqual("A256KW",bCaseSensitive) <> True) Then
    Debug.WriteLine("Rejecting JWE: key-management algorithm is not permitted by policy.")
    Exit Sub
End If

If (sbEnc.ContentsEqual("A256GCM",bCaseSensitive) <> True) Then
    Debug.WriteLine("Rejecting JWE: content-encryption algorithm is not permitted by policy.")
    Exit Sub
End If


'  Select an acceptable recipient.  For a multi-recipient JWE, FindRecipient locates the recipient
'  this application holds a key for by a per-recipient header value such as "kid".  A compact JWE
'  has a single recipient at index 0, so FindRecipient returns -1; fall back to index 0 in that case.
Dim recipientIndex As Integer = jwe.FindRecipient("kid","recipient-key-1",bCaseSensitive)
If (recipientIndex < 0) Then
    recipientIndex = 0
End If


'  Provide the key for the selected recipient.  In production, obtain the key from a secure source
'  rather than hard-coding it.
Dim base64Key As String = "YWJjZGVmZ2hpamtsbW5vcHFyc3R1dnd4eXowMTIzNDU="
success = jwe.SetWrappingKey(recipientIndex,base64Key,"base64")
If (success = False) Then
    Debug.WriteLine(jwe.LastErrorText)
    Exit Sub
End If


'  Decrypt the selected recipient and return the plaintext, decoded using the given charset.
Dim content As String = jwe.Decrypt(recipientIndex,"utf-8")
If (jwe.LastMethodSuccess = False) Then
    Debug.WriteLine(jwe.LastErrorText)
    Exit Sub
End If

Debug.WriteLine(content)