VB.NET

Fetch a Text IMAP Attachment as a String

Demonstrates the Chilkat Imap.FetchAttachmentString method, which returns one text attachment decoded to a string. The first argument is the Email, the second is the zero-based attachment index, and the third is the charset used to decode the bytes. This example returns the first attachment as a UTF-8 string.

Background: This is the convenient form when you simply want a small text attachment's content inline as a string. Only use it for attachments known to be text; decoding binary content through a charset can alter or corrupt the bytes. For binary data use FetchAttachmentBd, and for large text a StringBuilder (via FetchAttachmentSb) avoids an extra copy.

Chilkat VB.NET Downloads

Download Chilkat for VB.NET

VB.NET

Dim success As Boolean = False

'  Demonstrates the Imap.FetchAttachmentString method, which downloads one text attachment and
'  returns it decoded to a string.  The 1st argument is the Email, the 2nd is the zero-based
'  attachment index, and the 3rd is the charset used to decode the bytes.
'  
'  The message is fetched headers-only, then the attachment is downloaded on demand.

Dim imap As New Chilkat.Imap

imap.Ssl = True
imap.Port = 993

success = imap.Connect("imap.example.com")
If (success = False) Then
    Debug.WriteLine(imap.LastErrorText)
    Exit Sub
End If

success = imap.Login("user@example.com","myPassword")
If (success = False) Then
    Debug.WriteLine(imap.LastErrorText)
    Exit Sub
End If


success = imap.SelectMailbox("Inbox")
If (success = False) Then
    Debug.WriteLine(imap.LastErrorText)
    Exit Sub
End If


'  Fetch only the message headers.  Attachment bodies are NOT downloaded, but the ckx-imap-*
'  metadata describing the attachments is present, so the attachment info methods still work.
Dim headersOnly As Boolean = True
Dim useUid As Boolean = False
Dim seqNum As Integer = 1
Dim email As New Chilkat.Email
success = imap.FetchEmail(headersOnly,seqNum,useUid,email)
If (success = False) Then
    Debug.WriteLine(imap.LastErrorText)
    Exit Sub
End If


Dim numAttach As Integer = imap.GetMailNumAttach(email)
If (numAttach > 0) Then
    '  FetchAttachmentString returns a string, so assign it to a string variable.
    Dim attachText As String = imap.FetchAttachmentString(email,0,"utf-8")
    If (imap.LastMethodSuccess = False) Then
        Debug.WriteLine(imap.LastErrorText)
        Exit Sub
    End If

    Debug.WriteLine(attachText)
End If


success = imap.Disconnect()
If (success = False) Then
    Debug.WriteLine(imap.LastErrorText)
    Exit Sub
End If