VB.NET

HTTP Methods - GET and DELETE

Demonstrate a method for sending HTTP requests that don't have a request body, such as for GET or DELETE requests. VB.NET

Dim success As Boolean = False

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim http As New Chilkat.Http

' Specifiy a session log file so we can see the exact request/response
http.SessionLogFilename = "c:/aaworkarea/sessionLog.txt"

' Perhaps add a custom header or two..
http.SetRequestHeader("x-exz-date","20201012T235046Z")
http.SetRequestHeader("x-exz-id","1234")

' Send a GET request to https://www.example.com/someting?param1=123&param2=abc
Dim url As String = "https://www.example.com/someting?param1=123&param2=abc"
Dim resp As New Chilkat.HttpResponse
success = http.HttpNoBody("GET",url,resp)
If (success = False) Then
    Debug.WriteLine(http.LastErrorText)
    Exit Sub
End If


' The GET request that is sent looks like this.
' The Accept and Accept-Encoding headers are automatically added by default.

' 	GET /someting?param1=123&param2=abc HTTP/1.1
' 	Host: www.example.com
' 	Accept: */*
' 	Accept-Encoding: gzip
' 	x-exz-date: 20201012T235046Z
' 	x-exz-id: 1234

' Get the response status
Dim statusCode As Integer = resp.StatusCode
Debug.WriteLine("Response status: " & statusCode)

' Get the response body
Debug.WriteLine(resp.BodyStr)

' -------------------------------------------------------------
' Let's say we want to send a DELETE request, and we only want to accept an application/json response,
' and we don't want gzipped responses...

' First remove the previously specified custom headers.
http.ClearHeaders()

' Indicate we only accept application/json non-gzipped responses.
http.Accept = "application/json"
http.AllowGzip = False

' Send a DELETE request to https://www.example.com/deleteSomething
url = "https://www.example.com/deleteSomething"
success = http.HttpNoBody("DELETE",url,resp)
If (success = False) Then
    Debug.WriteLine(http.LastErrorText)
    Exit Sub
End If


' The DELETE request that is sent looks like this.
' The empty Accept-Encoding header value means we only want non-compressed responses.

' 	DELETE /deleteSomething HTTP/1.1
' 	Host: www.example.com
' 	Accept: application/json
' 	Accept-Encoding: 

' Get the response status
statusCode = resp.StatusCode
Debug.WriteLine("Response status: " & statusCode)

' Get the response body
Debug.WriteLine(resp.BodyStr)