VB.NET

Combine Timestamp Reply and Content File into a TimeStampData

See more ASN.1 Examples

Demonstrates how to combine a timestamp reply (RFC 3161) with a data file (any type of file) to create a TimeStampData structure (RFC 5544). VB.NET

Dim success As Boolean = False

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Also see this example:
' Send a TimeStamp Request to a TimeStamp Authority and get the Response

' Load a timestamp reply file
Dim bdTsr As New Chilkat.BinData
success = bdTsr.LoadFile("qa_data/tsd/sample.tsr")
If (success <> True) Then
    Debug.WriteLine("Failed to load timestamp reply file.")
    Exit Sub
End If


' Load the tsr into an ASN.1 object.
Dim asnTsr As New Chilkat.Asn
success = asnTsr.LoadEncoded(bdTsr.GetEncoded("base64"),"base64")
If (success <> True) Then
    Debug.WriteLine(asnTsr.LastErrorText)
    Exit Sub
End If


' Get the timestamp reply as XML.
Dim xmlTsr As New Chilkat.Xml
xmlTsr.LoadXml(asnTsr.AsnToXml())

' The timestamp reply XML begins like this:
' We'll want to remove the 1st "sequence" subtree.

'     <?xml version="1.0" encoding="utf-8"?>
'     <sequence>
'         <sequence>       <---- Remove this sub-tree.
'             <int>00</int>
'             <sequence>
'                 <utf8>Operation Okay</utf8>
'             </sequence>
'         </sequence>
'         <sequence>   
'             <oid>1.2.840.113549.1.7.2</oid>
'             <contextSpecific tag="0" constructed="1">
'             ...

' Remove the 1st sub-tree..
xmlTsr.RemoveChildByIndex(0)

' In this example, the data file we're combining with the timestamp into a timestampData is a .p7m.
' However, it can be any type of file (text or binary), it doesn't matter..
Dim bdContent As New Chilkat.BinData
success = bdContent.LoadFile("qa_data/tsd/sample.p7m")
If (success <> True) Then
    Debug.WriteLine("Failed to load content file.")
    Exit Sub
End If


' Begin building the TimeStampData.  
' We'll build as XML and then convert to ASN.1
Dim xml As New Chilkat.Xml
xml.Tag = "sequence"
xml.UpdateChildContent("oid","1.2.840.113549.1.9.16.1.31")
xml.UpdateAttrAt("contextSpecific",True,"tag","0")
xml.UpdateAttrAt("contextSpecific",True,"constructed","1")
xml.UpdateChildContent("contextSpecific|sequence|int","01")
xml.UpdateChildContent("contextSpecific|sequence|octets",bdContent.GetEncoded("base64"))
xml.UpdateAttrAt("contextSpecific|sequence|contextSpecific",True,"tag","0")
xml.UpdateAttrAt("contextSpecific|sequence|contextSpecific",True,"constructed","1")

Dim xContext As Chilkat.Xml = xml.GetChildWithTag("contextSpecific|sequence|contextSpecific")
xContext.AddChildTree(xmlTsr)


' Convert the XML to ASN.1
Dim tsd As New Chilkat.Asn
tsd.LoadAsnXml(xml.GetXml())

' Write the timestamped data to a file.
success = tsd.WriteBinaryDer("qa_output/sample.tsd")

' Alternatively, get the tsd ASN.1 as base64..
Dim tsdBase64 As String = tsd.GetEncodedDer("base64_mime")
Debug.WriteLine(tsdBase64)