(VB.NET) Create CAdES (p7m) Signature using ARSS (Aruba Remote Signing Service)

See more Signing in the Cloud Examples

Demonstrates creating a CAdES (p7m) signature using the Aruba Remote Signing Service.

Note: This example requires Chilkat v9.5.0.96 or later.

Chilkat .NET Downloads Chilkat .NET Assemblies Chilkat for .NET Core Chilkat for Mono

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Load the certificate used for signing.  The certificate's private key is stored on 
' the Aruba.it server and the signing will happen remotely using the
' ARSS (Aruba Remote Signing Service).
' However, we still need the certificate locally (without private key).
Dim cert As New Chilkat.Cert
Dim success As Boolean = cert.LoadFromFile("qa_data/certs/myCert.cer")
If (success = False) Then
    Debug.WriteLine(cert.LastErrorText)
    Exit Sub
End If


' To sign using the Aruba Remote Signing Service, 
' add the following lines of code to specify your authentication credentials,
' and the ID of the certificate w/ private key on the server to be used.
Dim jsonArss As New Chilkat.JsonObject

' Set the "service" equal to "ARSS" to tell Chilkat to use ARSS for signing.
jsonArss.UpdateString("service","ARSS")
' Specify the certificate ID, such as "AS0"
' This certificate should match the certificate loaded in the above code.
jsonArss.UpdateString("certID","YOUR_ARSS_CERT_ID")
jsonArss.UpdateString("otpPwd","YOUR_OTP_PWD")
jsonArss.UpdateString("typeOtpAuth","demoprod")
jsonArss.UpdateString("user","YOUR_ARSS_USERNAME")
jsonArss.UpdateString("userPWD","YOUR_ARSS_PASSWORD")
success = cert.SetCloudSigner(jsonArss)

Dim crypt As New Chilkat.Crypt2

success = crypt.SetSigningCert(cert)
If (success = False) Then
    Debug.WriteLine(crypt.LastErrorText)
    Exit Sub
End If


' The CadesEnabled property applies to all methods that create PKCS7 signatures. 
' To create a CAdES-BES signature, set this property equal to true.
crypt.CadesEnabled = True

crypt.HashAlgorithm = "sha256"

Dim signedAttrs As New Chilkat.JsonObject
signedAttrs.UpdateInt("contentType",1)
signedAttrs.UpdateInt("signingTime",1)
signedAttrs.UpdateInt("messageDigest",1)
signedAttrs.UpdateInt("signingCertificateV2",1)
crypt.SigningAttributes = signedAttrs.Emit()

' You can sign any type of file..
Dim inputXmlPath As String = "qa_data/e-Invoice.xml"
Dim outputP7mPath As String = "qa_output/signed.p7m"

' Create the CAdES-BES attached signature, which contains the original data.
' Chilkat will build the .p7m locally, but will (internally) use ARSS
' to do the RSA signing remotely.
success = crypt.CreateP7M(inputXmlPath,outputP7mPath)
If (success = False) Then
    Debug.WriteLine(crypt.LastErrorText)
    Exit Sub
End If


Debug.WriteLine("Success.")