Visual Basic 6.0

Iterate Through Matching ZIP Entries Using EntryMatching and ZipEntry.GetNextMatch

See more Zip Examples

This example demonstrates how to iterate through ZIP entries matching a wildcard pattern using:

• Zip.EntryMatching to obtain the first matching entry
• ZipEntry.GetNextMatch to advance to subsequent matching entries

The wildcard character * matches zero or more characters. Matching is performed against the full stored ZIP entry path.

The example searches for all entries beneath the docs/ directory.

Suppose the ZIP archive contains:

docs/
docs/readme.txt
docs/manual.pdf
docs/sub1/notes.txt
images/logo.png
hello.txt

The wildcard pattern:

docs/*

Matches:

docs/
docs/readme.txt
docs/manual.pdf
docs/sub1/notes.txt

Note that ZIP archives may optionally contain separate directory entries. Therefore, the first matching entry may be the directory entry docs/ rather than a file entry.

Visual Basic 6.0

Dim success As Long
success = 0

Dim zip As New ChilkatZip

' Open an existing ZIP archive.
success = zip.OpenZip("c:/temp/sample.zip")
If (success = 0) Then
    Debug.Print zip.LastErrorText
    Exit Sub
End If

' ------------------------------------------------------------
' Find the first ZIP entry matching the wildcard pattern:
' 
'     docs/*
' 
' Matching is performed against the full stored ZIP path.
' 
Dim entry As New ChilkatZipEntry

success = zip.EntryMatching("docs/*",entry)
If (success = 0) Then
    Debug.Print "No matching entries found."
    zip.CloseZip 
    Exit Sub
End If

' ------------------------------------------------------------
' Iterate through all matching entries.
' 
' GetNextMatch updates the same ZipEntry object so that
' it represents the next matching entry.
' 
Do While (success = 1)
    If (entry.IsDirectory = 1) Then
        Debug.Print "[Directory] " & entry.FileName
    Else
        Debug.Print "[File] " & entry.FileName
    End If

    ' Advance to the next matching entry.
    success = entry.GetNextMatch("docs/*")
Loop

zip.CloseZip 

Debug.Print "Done."