Visual Basic 6.0

Append Text Data to an Existing ZIP Entry Using ZipEntry.AppendString

See more Zip Examples

This example demonstrates how to use the ZipEntry.AppendString method to append text data to an existing ZIP entry.

The example opens an existing ZIP archive, locates a text file entry, and appends additional text to the end of the file contents.

An important concept demonstrated by this example is that appending data to a ZIP entry transforms the entry into an in-memory Data Entry (EntryType = 2).

For example:

• If the entry is a mapped entry from an opened ZIP archive (EntryType = 0), the compressed entry is first inflated into memory.
• If the entry is a referenced filesystem file (EntryType = 1), the file contents are first loaded into memory.

The new text is then appended to the uncompressed in-memory data, and the entry becomes a Data Entry.

After the ZIP archive is rewritten, the modified entry again becomes a mapped entry stored within the ZIP archive.

Visual Basic 6.0

Dim success As Long
success = 0

Dim zip As New ChilkatZip

' ------------------------------------------------------------
' Open an existing ZIP archive.
success = zip.OpenZip("c:/temp/notes.zip")
If (success = 0) Then
    Debug.Print zip.LastErrorText
    Exit Sub
End If

' Locate a text file entry within the ZIP archive.
Dim entry As New ChilkatZipEntry

success = zip.EntryOf("notes/readme.txt",entry)

If (success <> 0) Then

    ' --------------------------------------------------------
    ' At this point, the entry is a mapped entry because it
    ' originates from an opened ZIP archive.
    ' 
    '     EntryType = 0
    ' 
    Debug.Print "Initial EntryType = " & entry.EntryType

    ' Append additional text to the ZIP entry.
    ' 
    ' The existing compressed ZIP entry is first inflated
    ' into memory. The new text is then appended.
    ' 
    ' After AppendString is called, the entry becomes
    ' an in-memory Data Entry:
    ' 
    '     EntryType = 2
    ' 
    success = entry.AppendString(vbCrLf & "Additional notes added later.","utf-8")

    If (success = 0) Then
        Debug.Print zip.LastErrorText
        Exit Sub
    End If

    Debug.Print "EntryType after AppendString = " & entry.EntryType

    ' --------------------------------------------------------
    ' Write the modified ZIP archive to a different file.
    ' 
    ' Changing zip.FileName causes the ZIP archive to be
    ' written to a new output file rather than overwriting
    ' the original ZIP archive.
    ' 
    zip.FileName = "qa_output/updatedExample.zip"

    ' Rewrite the ZIP archive.
    ' 
    ' The modified in-memory entry is compressed and written
    ' into the new ZIP archive.
    ' 
    success = zip.WriteZip()
    If (success = 0) Then
        Debug.Print zip.LastErrorText
        Exit Sub
    End If

    ' After rewriting the ZIP archive, the entry again becomes
    ' a mapped entry:
    ' 
    '     EntryType = 0
    ' 
    Debug.Print "EntryType after WriteZip = " & entry.EntryType
End If

zip.CloseZip 

Debug.Print "ZIP entry updated successfully."