Visual Basic 6.0

XML SearchForTag Method

See more XML Examples

Demonstrates the SearchForTag and SearchForTag2 methods.

The input XML, available at http://www.chilkatsoft.com/data/fruitSearch.xml, is this:

<root>
    <searchRoot>
        <fruit color="red">apple</fruit>
        <fruit color="green">pear</fruit>
        <veg color="orange">carrot</veg>
        <meat animal="cow">beef</meat>
        <xyz>
            <fruit color="blue">blueberry</fruit>
            <veg color="green">broccoli</veg>
        </xyz>
        <fruit color="purple">grape</fruit>
        <cheese color="yellow">cheddar</cheese>
    </searchRoot>
    <fruit color="red">strawberry</fruit>
    <fruit color="orange">peach</fruit>
</root>

Visual Basic 6.0

Dim success As Long
success = 0

Dim xml As New ChilkatXml
Dim xSearchRoot As ChilkatXml
Dim xBeginAfter As ChilkatXml
Dim xFound As ChilkatXml

' The sample input XML is available at http://www.chilkatsoft.com/data/fruitSearch.xml
success = xml.LoadXmlFile("qa_data/xml/fruitSearch.xml")
If (success <> 1) Then
    Debug.Print xml.LastErrorText
    Exit Sub
End If

' Search the sub-tree rooted at "searchRoot"
Set xSearchRoot = xml.FindChild("searchRoot")

' Search for all nodes having the tag "fruit"
Set xBeginAfter = xSearchRoot.GetSelf()
Set xFound = xSearchRoot.SearchForTag(xSearchRoot,"fruit")
Do While (xSearchRoot.LastMethodSuccess = 1)

    Debug.Print xFound.Content

    Set xBeginAfter = xFound
    Set xFound = xSearchRoot.SearchForTag(xBeginAfter,"fruit")
Loop

Debug.Print "--------------------------"

' ---------------------------------------------------------------------------------
' Now do the same, but instead use SearchForTag2
' which updates the internal reference of the caller instead
' of returning the found node.
Dim xSearch As ChilkatXml

Set xBeginAfter = xSearchRoot.GetSelf()
Set xSearch = xSearchRoot.GetSelf()

success = xSearch.SearchForTag2(xBeginAfter,"fruit")
Do While success = 1

    Debug.Print xSearch.Content

    ' Copy the internal references so that the next search
    ' begins after the found node.
    xBeginAfter.CopyRef xSearch
    xSearch.CopyRef xSearchRoot

    success = xSearch.SearchForTag2(xBeginAfter,"fruit")
Loop