Visual Basic 6.0

WebSocket Connect through HTTP Proxy

See more WebSocket Examples

This example shows how to establish a WebSocket connection through an HTTP proxy server. Visual Basic 6.0

Dim success As Long
success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' --------------------------------------------------
' This example borrows the code from the REST using HTTP Proxy example.
' We first use the Chilkat Socket object to establish a connection to the WebSocket server through an HTTP proxy.
' Next, the Rest object uses the Socket object for its connection.
' Finally, the WebSocket object uses the Rest object for its connection.  
' 

Dim rest As New ChilkatRest
Dim socket As New ChilkatSocket

' Set the HTTP proxy domain or IP address, and port.
socket.HttpProxyHostname = "192.168.1.79"
socket.HttpProxyPort = 808

' Provide authentication to the HTTP proxy, if needed.
socket.HttpProxyUsername = "HTTP_PROXY_LOGIN"
socket.HttpProxyPassword = "HTTP_PROXY_PASSWORD"
socket.HttpProxyAuthMethod = "Basic"

' Indicate that HTTP requests (i.e. the WebSocket opening handshake) will be sent over the socket.
' This is important for how the HTTP proxy connection is established.
socket.HttpProxyForHttp = 1

' Connect to the websocket server through the HTTP proxy.
Dim bTls As Long
bTls = 0
Dim port As Long
port = 80
Dim maxWaitMs As Long
maxWaitMs = 5000
success = socket.Connect("some-websocket-server.com",port,bTls,maxWaitMs)
If (success <> 1) Then
    Debug.Print "Connect Failure Error Code: " & socket.ConnectFailReason
    Debug.Print socket.LastErrorText
    Exit Sub
End If

' Tell the Rest object to use the connected socket.
success = rest.UseConnection(socket,1)
If (success <> 1) Then
    Debug.Print rest.LastErrorText
    Exit Sub
End If

Dim ws As New ChilkatWebSocket

' Tell the WebSocket to use this connection.
success = ws.UseConnection(rest)
If (success <> 1) Then
    Debug.Print ws.LastErrorText
    Exit Sub
End If

' Add the standard WebSocket open handshake headers that will be needed.
' (This adds the required HTTP request headers to the rest object.)
success = ws.AddClientHeaders()

' Add any additional headers that might be desired.
' Two common WebSocketSpecific headers are "Sec-WebSocket-Protocol" and "Origin".
success = rest.AddHeader("Sec-WebSocket-Protocol","x-some-websocket-subprotocol")
success = rest.AddHeader("Origin","http://some-websocket-server.com")

' Do the open handshake.
Dim responseBody As String
responseBody = rest.FullRequestNoBody("GET","/something")
If (rest.LastMethodSuccess <> 1) Then
    Debug.Print rest.LastErrorText
    Exit Sub
End If

' If successful, the HTTP response status code should be 101,
' and the response body will be empty. (If it failed, we'll have a look
' at the response body..)
Dim statusCode As Long
statusCode = rest.ResponseStatusCode
Debug.Print "Response status code: " & statusCode

If (statusCode <> 101) Then
    Debug.Print responseBody
    Debug.Print "-- Failed because of unexpected response status code."
    Exit Sub
End If

' We have the expected 101 response, so let's now validate the 
' contents of the response, such as the value sent by the server in the
' Sec-WebSocket-Accept header. 
success = ws.ValidateServerHandshake()
If (success <> 1) Then
    Debug.Print ws.LastErrorText
    Exit Sub
End If

Debug.Print "WebSocket connection successful."

' The application may now begin sending and receiving frames on the WebSocket connection.
' (At this point, we're done with the rest and socket objects...)

Debug.Print "Success."