(Visual Basic 6.0) Stream a file to compression to encryption to an output file.

Runs a chain of streams to read a source file, compress, encrypt, and write an output file.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

Dim success As Long

' Initialize the compression object.
Dim compress As New ChilkatCompression
compress.Algorithm = "deflate"

' Initialize the encryption object.
Dim crypt As New ChilkatCrypt2
crypt.CryptAlgorithm = "chacha20"
crypt.KeyLength = 256
crypt.EncodingMode = "hex"
Dim ivHex As String
ivHex = "000000000000000000000002"
crypt.SetEncodedIV ivHex,"hex"
crypt.InitialCount = 42
Dim keyHex As String
keyHex = "1c9240a5eb55d38af333888604f6b5f0473917c1402b80099dca5cbc207075c0"
crypt.SetEncodedKey keyHex,"hex"

' Setup the streams.  
' streamC is for compression
Dim streamC As New ChilkatStream
' streamE is for encryption
Dim streamE As New ChilkatStream

' The source for the compressor is a file.
streamC.SourceFile = "qa_data/hamlet.xml"
' The source for the encryptor is the output of the compressor stream.
success = streamE.SetSourceStream(streamC)

' The sink for the encryptor is the output file.
streamE.SinkFile = "qa_output/compressed_encrypted.dat"

' Start the compression and encryption streams in background threads..
Dim taskC As ChilkatTask
Set taskC = compress.CompressStreamAsync(streamC)
Dim taskE As ChilkatTask
Set taskE = crypt.EncryptStreamAsync(streamE)
success = taskC.Run()
success = taskE.Run()

' Let the streams run until finished.
' Let's make sure the background task finished.
' It should already be the case that the task is finished.
Do While ((taskE.Finished <> 1) Or (taskC.Finished <> 1))
    taskE.SleepMs 20
Loop

' check for success..
If (taskE.TaskSuccess <> 1) Then
    Debug.Print "async encryption failed:"
    Debug.Print taskE.ResultErrorText
    success = 0
End If

' check for success..
If (taskC.TaskSuccess <> 1) Then
    Debug.Print "async compression failed:"
    Debug.Print taskC.ResultErrorText
    success = 0
End If

' Load the file that was produced and decrypt/decompress to verify.
Dim binData As New ChilkatBinData
success = binData.LoadFile("qa_output/compressed_encrypted.dat")
success = crypt.DecryptBd(binData)
success = compress.DecompressBd(binData)

' binData should contain the original data..
success = binData.WriteFile("qa_output/original_hamlet.xml")

Debug.Print "Finished."